/datum/universal_icon/New(icon/icon_file, icon_state="", dir=null, frame=null, datum/icon_transformer/transform=null, color=null)

/datum/controller/subsystem/processing/greyscale/proc/ExportMapPreviewsForType(filename, atom/atom_typepath, list/type_blacklist)
	var/list/handled_types = list()
	var/list/sprite_entries = list()
	for(var/atom/atom_type as anything in subtypesof(atom_typepath))
		if(type_blacklist && type_blacklist[atom_type])
			continue
		handled_types[atom_type] = TRUE
		var/greyscale_config = atom_type::greyscale_config
		var/greyscale_colors = atom_type::greyscale_colors
		if(!greyscale_config || !greyscale_colors || atom_type::flags_1 & NO_NEW_GAGS_PREVIEW_1)
			continue
		var/datum/universal_icon/map_icon = GetColoredIconByTypeUniversalIcon(greyscale_config, greyscale_colors, atom_type::post_init_icon_state)
		sprite_entries["[atom_type]"] = map_icon.to_list()

	// Skip empty sheets
	if(!length(sprite_entries))
		return handled_types

	var/entries_json = json_encode(sprite_entries)
	var/data_out = rustg_iconforge_generate("icons/map_icons/", filename, entries_json, FALSE, TRUE)
	if (data_out == RUSTG_JOB_ERROR)
		CRASH("GAGS-MapIcon/Spritesheet [filename] JOB PANIC")
	else if(!findtext(data_out, "{", 1, 2))
		rustg_file_write(entries_json, "[GLOB.log_directory]/spritesheet_gags_mapicon_debug_[replacetext(filename, "/", "-")].json")
		CRASH("GAGS-MapIcon/Spritesheet [filename] UNKNOWN ERROR: [data_out]")
	var/data = json_decode(data_out)
	var/list/sizes = data["sizes"]
	var/list/sprites = data["sprites"]
	if(data["error"])
		CRASH("Error during GAGS-MapIcon/spritesheet generation for [filename]: [data["error"]]")
	for(var/size_id in sizes)
		if(size_id == "32x32")
			continue
		fdel("icons/map_icons/[filename]_[size_id].dmi")
		var/list/sprites_with_bad_size = list()
		for(var/sprite_name in sprites)
			var/list/sprite = sprites[sprite_name]
			if(sprite["size_id"] == "32x32")
				continue
			sprites_with_bad_size.Add(sprite_name)
		var/bad_sprites = jointext(sprites_with_bad_size, " \n")
		CRASH("Non 32x32 icons found in GAGS-MapIcon/spritesheet [filename] for typepaths: \n[bad_sprites]")
	var/output_filepath = "icons/map_icons/[filename]_32x32.dmi"
	var/filepath = "icons/map_icons/[filename].dmi"
#ifdef UNIT_TESTS
	var/old_md5 = rustg_hash_file(RUSTG_HASH_MD5, filepath)
#endif
	fcopy(output_filepath, filepath)
#ifdef UNIT_TESTS
	var/new_md5 = rustg_hash_file(RUSTG_HASH_MD5, filepath)
	if(old_md5 != new_md5)
		stack_trace("Generated map icons were different than what is currently saved. If you see this in a CI run it means you need to run the game once through initialization and commit the resulting files in 'icons/map_icons/'")
#endif
	fdel(output_filepath)
	return handled_types