DynaPDF.WriteFTextEx
--------------------

Writes text on current page with formatting commands.

| Component | Version | macOS | Windows | Linux | Server | iOS SDK |
|---|---|---|---|---|---|---|
| [DynaPDF](component_DynaPDF.md) | [3.1](newinversion31.md) | ✅ Yes | ✅ Yes | ✅ Yes | ✅ Yes | ✅ Yes |

MBS( "DynaPDF.WriteFTextEx"; PDF; PosX; PosY; Width; Height; Align; Text { ; PlainText } ) 

**MBS**( **"DynaPDF.WriteFTextEx";** /\* Writes text on current page with formatting commands. \*/  
**$PDF**; /\* The PDF reference returned from [DynaPDF.New](DynaPDFNew.md). \*/   
**$PosX**; /\* X-Coordinate of output rectanglee.g. $x \*/   
**$PosY**; /\* Y-Coordinate of output rectanglee.g. $y \*/   
**$Width**; /\* Width of output rectanglee.g. $w \*/   
**$Height**; /\* Height of output rectangle or -1.e.g. $h \*/   
**$Align**; /\* The text alignment. Can be left, center, right or justify.e.g. "left" \*/   
**$Text**; /\* The text to write.e.g. "Hello World" \*/   
**$PlainText**) /\* Optional; Pass 1 to ignore formatting commands and treat text as plain text.  
Default is 0 to interpret commands in text.e.g. 0 \*/ 

### Parameters

| Parameter | Description | Example | Flags |
|---|---|---|---|
| PDF | The PDF reference returned from [DynaPDF.New](DynaPDFNew.md). | $pdf |  |
| PosX | X-Coordinate of output rectangle | $x |  |
| PosY | Y-Coordinate of output rectangle | $y |  |
| Width | Width of output rectangle | $w |  |
| Height | Height of output rectangle or -1. | $h |  |
| Align | The text alignment. Can be left, center, right or justify. | "left" |  |
| Text | The text to write. | "Hello World" |  |
| PlainText | Pass 1 to ignore formatting commands and treat text as plain text.   Default is 0 to interpret commands in text. | 0 | Optional      Added in version **9.1**. |

### Result

Returns OK or error message.

### Description

Writes text on current page with formatting commands.  
Use [DynaPDF.GetFTextHeightEx](DynaPDFGetFTextHeightEx.md) or [DynaPDF.GetFTextHeight](DynaPDFGetFTextHeight.md) to calculate the space needed for the text if you want to create a matching text rectangle for vertical alignment.  
  
See [DynaPDF.AllowPageBreak](DynaPDFAllowPageBreak.md) for whether to do page breaks or not.  
  
Please set a font first with [DynaPDF.SetFont](DynaPDFSetFont.md) function before you write on the page.  
See [DynaPDF.WriteStyledTextEx](DynaPDFWriteStyledTextEx.md) to convert FileMaker styles to DynaPDF commands.  
See also [WriteFTextEx](https://www.monkeybreadsoftware.com/DynaPDF-Manual/WriteFTextEx.shtml) function in DynaPDF manual.

### Examples

Write text in a rectangle:

 MBS ( "DynaPDF.WriteFTextEx"; $PDF ; 100; 500; 100; 100; "left"; "Hello World" )  
Loop over pages and add page numbers:

 Set Variable \[$PageCount ; Value:MBS ( "[DynaPDF.GetPageCount](DynaPDFGetPageCount.md)"; $pdf )\]  
Set Variable \[$PageNumber ; Value:1\]  
Set Variable \[$pageWidth ; Value:MBS ("[DynaPDF.GetPageWidth](DynaPDFGetPageWidth.md)"; $pdf )\]  
Set Variable \[$pageHeight ; Value:MBS ("[DynaPDF.GetPageHeight](DynaPDFGetPageHeight.md)"; $pdf )\]  
Loop  
 Set Variable \[$r ; Value:MBS ("[DynaPDF.EditPage](DynaPDFEditPage.md)"; $pdf ; $PageNumber )\]  
 Set Variable \[$r ; Value:MBS ( "[DynaPDF.SetFont](DynaPDFSetFont.md)"; $pdf ; "Helvetica"; 0; 12)\]  
 Set Variable \[$r ; Value:MBS ( "DynaPDF.WriteFTextEx"; $pdf ; 50; $pageHeight - 50; $pageWidth -100; 30; "right"; GetAsText($PageNumber ) &amp; " of " &amp; $PageCount )\]  
 Set Variable \[$r ; Value:MBS ("[DynaPDF.EndPage](DynaPDFEndPage.md)"; $pdf )\]  
 Set Variable \[$PageNumber ; Value:$PageNumber +1\]  
 Exit Loop If \[$PageNumber &gt; $PageCount \]  
End Loop  
Annotate PDF page with text on top center:

 # make pdf   
Set Field \[PDF::Annotated PDF; PDF::Original PDF\]  
\#Clear current PDF document   
Set Variable \[$pdf ; Value:MBS ("[DynaPDF.New](DynaPDFNew.md)")\]  
\#Load PDF from container   
Set Variable \[$r ; Value:MBS ("[DynaPDF.OpenPDFFromContainer](DynaPDFOpenPDFFromContainer.md)"; $pdf ; PDF::Original PDF)\]  
Set Variable \[$r ; Value:MBS ("[DynaPDF.ImportPDFFile](DynaPDFImportPDFFile.md)"; $pdf )\]  
\# write on each page a header   
Set Variable \[$index ; Value:1\]  
Set Variable \[$count ; Value:MBS ("[DynaPDF.GetPageCount](DynaPDFGetPageCount.md)"; $pdf )\]  
Loop  
 Set Variable \[$r ; Value:MBS ("[DynaPDF.EditPage](DynaPDFEditPage.md)"; $pdf ; $index )\]  
 Set Variable \[$r ; Value:MBS ("[DynaPDF.SetPageCoords](DynaPDFSetPageCoords.md)"; $pdf ; "topdown")\]  
 Set Variable \[$r ; Value:MBS ("[DynaPDF.SetFont](DynaPDFSetFont.md)"; $pdf ; "Arial"; 0; 10; 1; "unicode")\]  
 Set Variable \[$PageWidth ; Value:MBS ("[DynaPDF.GetPageWidth](DynaPDFGetPageWidth.md)"; $pdf )\]  
 Set Variable \[$print ; Value:MBS ("DynaPDF.WriteFTextEx"; $pdf ; 0; 20; $PageWidth ; -1; "center"; "Doc - " &amp; PDF::PK &amp; "")\]  
 Set Variable \[$r ; Value:MBS ("[DynaPDF.EndPage](DynaPDFEndPage.md)"; $pdf )\]  
 Set Variable \[$index ; Value:$index + 1\]  
 Exit Loop If \[$index &gt; $count \]  
End Loop  
\#save   
Set Field \[PDF::Annotated PDF; MBS ( "[DynaPDF.Save](DynaPDFSave.md)"; $PDF ; "print.pdf" )\]  
\#Cleanup   
Set Variable \[$r ; Value:MBS ("[DynaPDF.Release](DynaPDFRelease.md)"; $pdf )\]  
Write some text with a link:

 MBS ( "DynaPDF.WriteFTextEx"; $PDF ; 100; 500; 100; 100; "left"; "Link to DynaPDF: \\FC\[16711680\]\\ul#\\LK\[false, TRUE, false, https://www.dynaforms.com\]Test\\EK#\\ul#\\FC\[0\]." )  
Write text in RGB colors:

 Set Variable \[ $r ; Value: MBS ("[DynaPDF.SetColorSpace](DynaPDFSetColorSpace.md)"; $pdf ; "DeviceRGB") \]   
\# calculate color values for RBB   
Set Variable \[ $red ; Value: MBS ( "[DynaPDF.RGB](DynaPDFRGB.md)"; 255; 0; 0 ) \]   
Set Variable \[ $green ; Value: MBS ( "[DynaPDF.RGB](DynaPDFRGB.md)"; 0; 255; 0 ) \]   
Set Variable \[ $blue ; Value: MBS ( "[DynaPDF.RGB](DynaPDFRGB.md)"; 0; 0; 255 ) \]   
\# now write some text   
Set Variable \[ $r ; Value: MBS ("DynaPDF.DynaPDF.WriteFTextEx"; $pdf ; 100; 100; 500; 200;   
 "left"; "Testing: " &amp;   
 "\\FC\[" &amp; $red &amp; "\]Red" &amp;   
 "\\FC\[" &amp; $green &amp; "\]Green" &amp;   
 "\\FC\[" &amp; $blue &amp; "\]Blue" ) \]  
Write text in CMYK colors:

 # set colorspace   
Set Variable \[ $r ; Value: MBS ("[DynaPDF.SetColorSpace](DynaPDFSetColorSpace.md)"; $pdf ; "DeviceCMYK") \]   
  
\# calculate color values for CMYK   
Set Variable \[ $cyan ; Value: MBS ( "[DynaPDF.CMYK](DynaPDFCMYK.md)"; 255; 0; 0; 0 ) \]   
Set Variable \[ $magenta ; Value: MBS ( "[DynaPDF.CMYK](DynaPDFCMYK.md)"; 0; 255; 0; 0 ) \]   
Set Variable \[ $yellow ; Value: MBS ( "[DynaPDF.CMYK](DynaPDFCMYK.md)"; 0; 0; 255; 0 ) \]   
Set Variable \[ $black ; Value: MBS ( "[DynaPDF.CMYK](DynaPDFCMYK.md)"; 0; 0; 0; 255 ) \]   
  
\# now write some text   
Set Variable \[ $r ; Value: MBS ("DynaPDF.DynaPDF.WriteFTextEx"; $pdf ; 100; 100; 500; 200;   
 "left"; "Testing: " &amp;   
 "\\FC\[" &amp; $cyan &amp; "\]Cyan" &amp;   
 "\\FC\[" &amp; $Magenta &amp; "\]Magenta" &amp;   
 "\\FC\[" &amp; $Yellow &amp; "\]Yellow" &amp;   
 "\\FC\[" &amp; $Black &amp; "\]Black" ) \]  
Draw page number inside a round rectangle box:

 # set color white to fill and light gray for frame   
Set Variable \[ $r ; Value: MBS ( "[DynaPDF.SetStrokeColor](DynaPDFSetStrokeColor.md)"; $pdf ; ,1; ,1; ,1) \]   
Set Variable \[ $r ; Value: MBS ( "[DynaPDF.SetFillColor](DynaPDFSetFillColor.md)"; $pdf ; 1; 1; 1) \]   
\# draw round rect with one point border   
Set Variable \[ $r ; Value: MBS ( "[DynaPDF.SetLineWidth](DynaPDFSetLineWidth.md)"; $pdf ; 1) \]   
Set Variable \[ $r ; Value: MBS ( "[DynaPDF.RoundRectEx](DynaPDFRoundRectEx.md)"; $pdf ; 50; $pageHeight - 50; $pageWidth - 100; 30; 5; 5; "FillStroke" ) \]   
\#   
\# set color black   
Set Variable \[ $r ; Value: MBS ( "[DynaPDF.SetStrokeColor](DynaPDFSetStrokeColor.md)"; $pdf ; 0; 0; 0) \]   
Set Variable \[ $r ; Value: MBS ( "[DynaPDF.SetFillColor](DynaPDFSetFillColor.md)"; $pdf ; 0; 0; 0) \]   
\# and write centered text   
Set Variable \[ $r ; Value: MBS ( "[DynaPDF.SetFont](DynaPDFSetFont.md)"; $pdf ; "Helvetica"; 0; 20) \]   
Set Variable \[ $r ; Value: MBS ( "DynaPDF.WriteFTextEx"; $pdf ; 50; $pageHeight - 50; $pageWidth -100; 30; "center"; GetAsText($PageNumber ) &amp; " of " &amp; $PageCount ) \]  
Render text block as image:

 Set Variable \[ $pdf ; Value: MBS ("[DynaPDF.New](DynaPDFNew.md)") \]  
\# Add page   
Set Variable \[ $r ; Value: MBS ("[DynaPDF.AppendPage](DynaPDFAppendPage.md)"; $pdf ) \]  
Set Variable \[ $r ; Value: MBS ("[DynaPDF.SetPageCoords](DynaPDFSetPageCoords.md)"; $pdf ; "topdown") \]  
Set Variable \[ $r ; Value: MBS ("[DynaPDF.SetFont](DynaPDFSetFont.md)"; $pdf ; "Helvetica"; 0; 12) \]  
\# Write some text   
Set Variable \[ $text ; Value: "The award winning \\FT\[Helvetica:1\]MBS Plugin\\FT\[Helvetica:0\] is easily the most powerful plug-in available for Claris FileMaker today. There are over 7,700 functions that allow Claris FileMaker developers to extend their solutions in some amazing ways. …" \]  
Set Variable \[ $r ; Value: MBS ("[DynaPDF.SetFillColor](DynaPDFSetFillColor.md)"; $pdf ; 0; 0; 0) \]  
Set Variable \[ $r ; Value: MBS ("DynaPDF.WriteFTextEx"; $pdf ; 10; 10; 300; -1; "justify"; $Text ) \]  
\# now figure out how much space we needed to make the page the right size   
Set Variable \[ $height ; Value: MBS ("[DynaPDF.GetLastTextPosY](DynaPDFGetLastTextPosY.md)"; $pdf ) \]  
Set Variable \[ $ph ; Value: MBS ("[DynaPDF.GetPageHeight](DynaPDFGetPageHeight.md)"; $pdf ) \]  
Set Variable \[ $r ; Value: MBS ( "[DynaPDF.SetBBox](DynaPDFSetBBox.md)"; $PDF ; "Media"; 0; $ph ; 320; $height - 10 ) \]  
\# close page, document and save PDF   
Set Variable \[ $r ; Value: MBS ("[DynaPDF.EndPage](DynaPDFEndPage.md)"; $pdf ) \]  
\# render a picture   
Set Variable \[ $Result ; Value: MBS ("[DynaPDF.RenderPage](DynaPDFRenderPage.md)"; $pdf ; 1; 150) \]  
\#   
Set Variable \[ $r ; Value: MBS ("[DynaPDF.Release](DynaPDFRelease.md)"; $pdf ) \]  
\# Put in Container   
Set Field \[ Create Text::PDF ; $Result \]  
Create certificate with script:

 # Initialize DynaPDF if needed   
If \[ MBS ("[DynaPDF.IsInitialized](DynaPDFIsInitialized.md)") ≠ 1 \]  
 Perform Script \[ “InitDynaPDF” ; Specified: From list ; Parameter: \]  
End If  
\# Clear current PDF document   
Set Variable \[ $pdf ; Value: MBS ("[DynaPDF.New](DynaPDFNew.md)") \]  
\# Load template   
Set Variable \[ $r ; Value: MBS ("[DynaPDF.OpenPDFFromFile](DynaPDFOpenPDFFromFile.md)"; $pdf ; "/Users/cs/Test/Template.pdf") \]  
Set Variable \[ $r ; Value: MBS ("[DynaPDF.ImportPDFFile](DynaPDFImportPDFFile.md)"; $pdf ; 1) \]  
\# Edit page to add text   
Set Variable \[ $r ; Value: MBS ("[DynaPDF.EditPage](DynaPDFEditPage.md)"; $pdf ; 1) \]  
Set Variable \[ $r ; Value: MBS ("[DynaPDF.SetFont](DynaPDFSetFont.md)"; $pdf ; "SignPainter-HouseScript"; 0; 20) \]  
Set Variable \[ $r ; Value: MBS ("DynaPDF.WriteFTextEx"; $pdf ; 144; 160; 170; 30; "Center"; Get(CurrentDate) ) \]  
Set Variable \[ $r ; Value: MBS ("DynaPDF.WriteFTextEx"; $pdf ; 528; 160; 170; 30; "Center"; "Christian Schmitz" ) \]  
Set Variable \[ $r ; Value: MBS ("DynaPDF.WriteFTextEx"; $pdf ; 132; 220; 576; 50; "Center"; "FileMaker AI Development" ) \]  
\# and name   
Set Variable \[ $r ; Value: MBS ("[DynaPDF.SetFont](DynaPDFSetFont.md)"; $pdf ; "SignPainter-HouseScript"; 0; 30) \]  
Set Variable \[ $r ; Value: MBS ("DynaPDF.WriteFTextEx"; $pdf ; 132; 320; 576; 50; "Center"; "John Miller" ) \]  
\# Close page and save   
Set Variable \[ $r ; Value: MBS ("[DynaPDF.EndPage](DynaPDFEndPage.md)"; $pdf ) \]  
Set Variable \[ $PDFData ; Value: MBS ("[DynaPDF.Save](DynaPDFSave.md)"; $pdf ; "certificate.pdf") \]  
Set Variable \[ $r ; Value: MBS ("[DynaPDF.Release](DynaPDFRelease.md)"; $pdf ) \]  
\# Put in Container   
Set Field \[ WriteFText::PDF ; $PDFData \]  
Create certificate with calculation:

 Let(\[  
 // Clear current PDF document  
 pdf = MBS ("[DynaPDF.New](DynaPDFNew.md)");  
 // Load template  
 r = MBS ("[DynaPDF.OpenPDFFromFile](DynaPDFOpenPDFFromFile.md)"; $pdf ; "/Users/cs/Test/Template.pdf");  
 r = MBS ("[DynaPDF.ImportPDFFile](DynaPDFImportPDFFile.md)"; $pdf ; 1);  
 // Edit page to add text  
 r = MBS ("[DynaPDF.EditPage](DynaPDFEditPage.md)"; $pdf ; 1);  
 r = MBS ("[DynaPDF.SetFont](DynaPDFSetFont.md)"; $pdf ; "SignPainter-HouseScript"; 0; 20);  
 r = MBS ("DynaPDF.WriteFTextEx"; $pdf ; 144; 160; 170; 30; "Center"; Get(CurrentDate) );  
 r = MBS ("DynaPDF.WriteFTextEx"; $pdf ; 528; 160; 170; 30; "Center"; "Christian Schmitz" );  
 r = MBS ("DynaPDF.WriteFTextEx"; $pdf ; 132; 220; 576; 50; "Center"; "FileMaker AI Development" );  
 // and name  
 r = MBS ("[DynaPDF.SetFont](DynaPDFSetFont.md)"; $pdf ; "SignPainter-HouseScript"; 0; 30);  
 r = MBS ("DynaPDF.WriteFTextEx"; $pdf ; 132; 320; 576; 50; "Center"; "John Miller" );  
 // Close page and save  
 r = MBS ("[DynaPDF.EndPage](DynaPDFEndPage.md)"; $pdf );  
 PDFData = MBS ("[DynaPDF.Save](DynaPDFSave.md)"; $pdf ; "certificate.pdf");  
 r = MBS ("[DynaPDF.Release](DynaPDFRelease.md)"; $pdf )  
\]; PDFData)  
### See also

- [DynaPDF.SetColorSpace](DynaPDFSetColorSpace.md)
- [DynaPDF.SetFillColor](DynaPDFSetFillColor.md)
- [DynaPDF.SetFont](DynaPDFSetFont.md)
- [DynaPDF.SetPageBreakExpression](DynaPDFSetPageBreakExpression.md)
- [DynaPDF.SetPageCoords](DynaPDFSetPageCoords.md)
- [DynaPDF.SetStrokeColor](DynaPDFSetStrokeColor.md)
- [DynaPDF.WebLink](DynaPDFWebLink.md)
- [DynaPDF.WriteFTextExRotated](DynaPDFWriteFTextExRotated.md)
- [DynaPDF.WriteStyledText](DynaPDFWriteStyledText.md)
- [DynaPDF.WriteText](DynaPDFWriteText.md)

### Release notes

- **Version 9.1**
    - Added PlainText flag to [DynaPDF.WriteFText](http://www.mbsplugins.eu/DynaPDFWriteFText.shtml), [DynaPDF.WriteFTextEx](http://www.mbsplugins.eu/DynaPDFWriteFTextEx.shtml) and [DynaPDF.WriteFTextExRotated](http://www.mbsplugins.eu/DynaPDFWriteFTextExRotated.shtml) functions.
- **Version 7.4**
    - Added [DynaPDF.WriteFTextExRotated](http://www.mbsplugins.eu/DynaPDFWriteFTextExRotated.shtml) and [DynaPDF.WriteStyledTextExRotated](http://www.mbsplugins.eu/DynaPDFWriteStyledTextExRotated.shtml).

### Example Databases

- [Barcode/DynaPDF Barcode](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/Barcode/DynaPDF%20Barcode.shtml#2ScriptAnchor_)
- [DynaPDF/Add Page Numbers](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/DynaPDF/Add%20Page%20Numbers.shtml#2ScriptAnchor_)
- [DynaPDF/Book Creation](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/DynaPDF/Book%20Creation.shtml#3ScriptAnchor_)
- [DynaPDF/Catalog with tables](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/DynaPDF/Catalog%20with%20tables.shtml#1ScriptAnchor_)
- [DynaPDF/Create Text as PDFA](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/DynaPDF/Create%20Text%20as%20PDFA.shtml#7ScriptAnchor_)
- [DynaPDF/Invoice/Invoice](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/DynaPDF/Invoice/Invoice.shtml#3ScriptAnchor_)
- [DynaPDF/Merge PDFs](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/DynaPDF/Merge%20PDFs.shtml#8ScriptAnchor_)
- [DynaPDF/Report](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/DynaPDF/Report.shtml#1ScriptAnchor_)
- [DynaPDF/Shrink PDF pages](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/DynaPDF/Shrink%20PDF%20pages.shtml#2ScriptAnchor_)
- [DynaPDF/Signature Appearance](https://www.mbsplugins.eu/MBS-FileMaker-Plugin-Examples/DynaPDF/Signature%20Appearance.shtml#1ScriptAnchor_)

### Blog Entries

- [Make PDF certificates in calculation with DynaPDF](https://www.mbsplugins.de/archive/2026-05-18/Make_PDF_certificates_in_calcu/monkeybreadsoftware_blog_filemaker)
- [Draw images with text using DynaPDF](https://www.mbsplugins.de/archive/2026-01-03/Draw_images_with_text_using_Dy/monkeybreadsoftware_blog_filemaker)
- [MBS Plugin Advent calendar: 15 - DynaPDF](https://www.mbsplugins.de/archive/2023-12-15/MBS_Plugin_Advent_calendar_15_/monkeybreadsoftware_blog_filemaker)
- [Merge documents with DynaPDF](https://www.mbsplugins.de/archive/2023-07-06/Merge_documents_with_DynaPDF/monkeybreadsoftware_blog_filemaker)
- [Things you can do with DynaPDF](https://www.mbsplugins.de/archive/2021-07-02/Things_you_can_do_with_DynaPDF/monkeybreadsoftware_blog_filemaker)
- [New in MBS FileMaker Plugin 11.0](https://www.mbsplugins.de/archive/2021-01-26/New_in_MBS_FileMaker_Plugin_11/monkeybreadsoftware_blog_filemaker)
- [New in MBS FileMaker Plugin 10.5](https://www.mbsplugins.de/archive/2020-11-23/New_in_MBS_FileMaker_Plugin_10/monkeybreadsoftware_blog_filemaker)
- [Example Script for DynaPDF.FindText and DynaPDF.WebLink](https://www.mbsplugins.de/archive/2020-05-04/Example_Script_for_DynaPDFFind/monkeybreadsoftware_blog_filemaker)
- [MBS FileMaker Plugin, version 9.1pr2](https://www.mbsplugins.de/archive/2019-02-11/MBS_FileMaker_Plugin_version_9/monkeybreadsoftware_blog_filemaker)

### FileMaker Magazin

- [Ausgabe 5/2021, Seite 28](https://filemaker-magazin.de/neuigkeit/4158-Appetithappen-FMM_202105)
- [Ausgabe 6/2020, Seite 26](https://filemaker-magazin.de/neuigkeit/4118-Appetithappen-FMM_202006)
- [Ausgabe 3/2019, Seite 38](https://filemaker-magazin.de/neuigkeit/4046-Appetithappen-FMM_201903)
- [Ausgabe 2/2019, Seite 27](https://filemaker-magazin.de/neuigkeit/4043-Appetithappen-FMM_201902)

This function checks for a license.

Created 18th August 2014 , last changed 12nd April 2026

  
[DynaPDF.WriteFText](DynaPDFWriteFText.md) - [DynaPDF.WriteFTextExRotated](DynaPDFWriteFTextExRotated.md)

[HTML Version](DynaPDFWriteFTextEx.shtml)