S2 Layouts on LiveJournal.com

a moony kunundrum

kunzite1 — Wed, 17 Aug 2005 20:18:44 GMT

changes:
property-ified hard-coded english
added tag support
linkbar for all entries
local vars in print_entry() for selecting recent/friends/day/entry/reply userpics

todo:
ajax comments
quick reply

# -*-s2-*-

layerinfo "type"            = "layout";
layerinfo "name"            = "A Moony Kunundrum";
layerinfo "source_viewable" = 1;
layerinfo "redist_uniq"     = "anovelconundrum/layout";
layerinfo "author_name"     = "taion/edited by kunzite1";

propgroup colors {
  property Color page_back {
    des = "Page background";
  }
  property Color entry_text {
    des = "Entry text color";
  }
  property Color text_weaker {
    des = "Weaker text color";
  }
  property Color page_link {
    des = "Link color";
  }
  property Color page_vlink {
    des = "Visited link color";
  }
  property Color page_alink {
    des = "Active link color";
  }
}

# From my last e-mail with Taion, the plan was to rasterize the leading fonts so that
# appearance issues could be avoided. However, I don't have access to many of the fonts
# that he tested with, so I'll have to put that off for later.

# You will need access to Microsoft provided fonts for most accurate rendering, but
# we are working on specifying usable alternatives that are cross platform friendly.
propgroup fonts {
  property use font_base;
  property string font_fallback {
    des = "Alternative font style";
  }
  property string font_type {
    des = "Body font type";
    note = "General font class for body text";
  }
  property int font_size {
    des = "Body font size (points)";
  }
  property int font_leading {
    des = "Body font leading (points)";
  }
  property string title_letterspacing {
    des = "Letterspacing in titles";
  }
  property bool title_smallcaps {
    des = "Smallcaps in titles";
  }
  property bool title_underline {
    des = "Underlined titles";
  }
  property string font_flourish_base {
    des = "Font face for decorative flourishes";
  }
  property string font_flourish_fallback {
    des = "Alternate font face for decorative flourishes";
  }
  property string font_flourish_type {
    des = "Font type for decorative flourishes";
  }
  property string font_secondary_base {
    des = "Font face for secondary text";
  }
  property string font_secondary_fallback {
    des = "Alternate font face for secondary text";
  }
  property string font_secondary_type {
    des = "Font type for secondary text";
  }
  property int font_secondary_size {
    des = "Secondary font size (points)";
    note = "For best results, match optical x-height with the body font";
  }
  property string flourish_rm {
    des = "Right margin for flourishes";
  }
  property string dc_rm {
    des = "Right margin for drop caps";
  }
}

propgroup presentation {
  property string dingbar_url { 
    des = "URL to spacer image between portions of content";
    note = "A default will be chosen for you if left blank.";
  }

  property use page_recent_items;
  property use page_friends_items;
  property use tags_aware;

  property string body_width {
    des = "Text body width";
  }

  property int dcLen {
    des = "Minimum length in characters before using drop caps";
  }

  property use view_entry_disabled;
  property use use_shared_pic;
  property use comment_userpic_style;
  property bool show_entrynav_icons {
    des = "Toggle to show the next, memory, edit, etc icons on the entry view page";
  }
  property string page_background_image {
    des = "URL to an image to be used for the page background";
  }
  property use external_stylesheet;
}

propgroup text {
  property use text_post_comment;
  property use text_read_comments;
  property use text_post_comment_friends;
  property use text_read_comments_friends;
  property use text_meta_music;
  property use text_meta_mood;
  property string text_seperator {
    des = "Text used to seperate stuff";
  }
  property string text_years_header {
    des = "Text used for Years header";
  }
  property string text_comment_screened {
    des = "Text used for donoting a screened comment";
  }
  property string text_comment_commented {
    des = "Text used for 'commented'";
  }
  property string text_comment_replied {
    des = "Text used for 'replied'";
  }
  property string text_comment_on {
    des = "Text used for 'on'";
  }
  property string text_reply_reply {
    des = "Text used for 'Reply'";
  }
  property string text_reply_entry {
    des = "Text used for 'to this entry'";
  }
  property string text_reply_comment {
    des = "Text used for 'to this comment'";
  }
  property string text_dingbar_alt {
    des = "Alternative text for dingbar images";
    noui = 1;
  }
}

# Set default colors
set entry_text              = "#000000";
set text_weaker             = "#666666";
set page_alink              = "#333333";
set page_back               = "#f5f5dc";
set page_link               = "#000000";
set page_vlink              = "#666666";

set body_width              = "35em";
set dcLen                   = 200;
set show_entrynav_icons     = true;
set page_background_image   = "";
set tags_aware              = true;

set dc_rm                   = "0.2em";
set dingbar_url             = "";
set flourish_rm             = "0.093em";
set font_base               = "Palatino Linotype";
set font_fallback           = "Book Antiqua";
set font_flourish_base      = "Edwardian Script ITC\", \"Edwardian Script ITC Semi-Expanded";
set font_flourish_fallback  = "Zapfino\", \"Viner Hand ITC";
set font_flourish_type      = "cursive";
set font_leading            = 14;
set font_secondary_base     = "Frutiger Linotype";
set font_secondary_fallback = "Tahoma";
set font_secondary_size     = 9;
set font_secondary_type     = "sans-serif";
set font_size               = 10;
set font_type               = "serif";
set title_letterspacing     = "0.08em";
set title_smallcaps         = true;
set title_underline         = false;

set text_dingbar_alt        = "* * *";
set text_meta_mood          = "Current Mood:";
set text_meta_music         = "Current Music:";
set text_poster_anonymous   = "an anonymous reader";
set text_seperator          = " &middot; ";
set text_view_archive       = "Archive";
set text_view_friends       = "Friends";
set text_view_recent        = "Entries";
set text_view_userinfo      = "Profile";
set text_years_header       = "Years";
set text_comment_screened   = "(Screened)";
set text_comment_commented  = "commented";
set text_comment_replied    = "replied";
set text_comment_on         = "&mdash;&thinsp;On";
set text_reply_reply        = "Reply";
set text_reply_entry        = "to this entry";
set text_reply_comment      = "to this comment";

function prop_init() {
  var PalItem start = PalItem(0, $*entry_text);
  var PalItem end   = PalItem(13, $*page_back);
    if ($*dingbar_url == "") { $*dingbar_url = palimg_gradient("anovelconundrum/dingbar.gif", $start, $end); }
}

function print_stylesheet() {
  print clean_url($*page_background_image) != "" ? "body { background-image: url($*page_background_image); }" : "";
"""
body {
  margin-top:    1in;
  margin-bottom: 0.6in;
}

body, td, h2, .caption, h1, h3 {
""";
if ($*font_base != "" or $*font_fallback != "" or $*font_type != "") {
    "font-family: ";
    if ($*font_base != "") {
        "\"$*font_base\"";
        if ($*font_fallback != "" or $*font_type != "") {
            ", ";
        }
    }
    if ($*font_fallback != "") {
        "\"$*font_fallback\"";
        if ($*font_type != "") {
            ", ";
        }
    }
    if ($*font_type != "") {
        "$*font_type";
    }
    ";\n";
}
"""
  font-size:   ${*font_size}pt;
  line-height: ${*font_leading}pt;
  font-weight: normal;
}

.caption, h1, h3 {
"""; if($*title_smallcaps) {"""
  font-variant:   small-caps;
  text-transform: lowercase;
"""; }
"""  letter-spacing: $*title_letterspacing;
}
h1 { font-size: 16pt; }
h3 { font-size: 12pt; }
h2, .noul, .ult {
  font-style: italic;
  margin:     0px;
}

.caption {
"""; if($*title_underline) {"""
  text-decoration: underline;
"""; }
""" }

.flourish, .bodyl:first-letter {
""";
if ($*font_flourish_base != "" or $*font_flourish_fallback != "" or $*font_flourish_type != "") {
    "font-family: ";
    if ($*font_flourish_base != "") {
        "\"$*font_flourish_base\"";
        if ($*font_flourish_fallback != "" or $*font_flourish_type != "") {
            ", ";
        }
    }
    if ($*font_flourish_fallback != "") {
        "\"$*font_flourish_fallback\"";
        if ($*font_flourish_type != "") {
            ", ";
        }
    }
    if ($*font_flourish_type != "") {
        "$*font_flourish_type";
    }
    ";\n";
}
"""
}

.flourish {
  margin-right:   ${*flourish_rm};
  z-index:        1;
  font-size:      34pt;
  position:       relative;
  top:            0.1em;
  text-transform: uppercase;
}

.sfon, .index, .author, select, input {
""";
if ($*font_secondary_base != "" or $*font_secondary_fallback != "" or $*font_secondary_type != "") {
    "font-family: ";
    if ($*font_secondary_base != "") {
        "\"$*font_secondary_base\"";
        if ($*font_secondary_fallback != "" or $*font_secondary_type != "") {
            ", ";
        }
    }
    if ($*font_secondary_fallback != "") {
        "\"$*font_secondary_fallback\"";
        if ($*font_secondary_type != "") {
            ", ";
        }
    }
    if ($*font_secondary_type != "") {
        "$*font_secondary_type";
    }
    ";\n";
}
""" font-size: ${*font_secondary_size}pt;

  line-height: ${*font_leading}pt;
}

.index {
  width:        10em;
  margin-right:  1.2em;
}

.bodybox { width: $*body_width; }

.body, .bodyl, .bodyns {
  text-align: justify;
}
.bodyl:first-letter {
  font-size:      """ + (2* $*font_leading) + """pt;
  margin-bottom:  -""" + $*font_size + """pt;
  margin-right:   ${*dc_rm};
  float:          left;
  border-bottom:  none;
  text-transform: uppercase;
  line-height:    """ + (2* $*font_leading) + """pt;
}
.bodyns:first-line, .sc, small, .sct {
"""; if($*title_smallcaps) {"""
  font-variant:   small-caps;
  text-transform: lowercase;
"""; }
    if($*title_underline) {"""
  text-decoration: underline;
"""; }
"""  letter-spacing: 0.05em;
}

.sct {
  letter-spacing: $*title_letterspacing;
  text-align:     center;
}

.author {
  float:         right;
  text-align:    center;
  margin-left:   1.5em;
  margin-bottom: 0.5em;
}

.ywp {
  width:          2em;
  margin-left:  0.5em;
  margin-right: 0.5em;
}

blockquote {
  margin-top:    ${*font_leading}pt;
  margin-bottom: ${*font_leading}pt;
  margin-left:   2em;
}

tt, pre, textarea {
  font-family: "Lucida Console", monospace;
  font-size:"""+ ((${*font_size}*4)/5) + """pt;
}

a {text-decoration: none;}
.body a, .bodyl a, .bodyns a, .bodynsl a, .author a, .ult a, .uts a { border-bottom: 1px dotted; }
.ljuser a, a img, .smallbar a, .noul a { border-bottom: none; }
a:hover, .ljuser a:hover { border-bottom: 1px solid; }

p {
  text-indent: 1.5em;
  margin:        0px;
  padding:       0px;
}

blockquote + p { text-indent: 0px; }

.uts {
  font-size:     80%;
  font-style:    italic;
  text-align:    center;
  line-height:   """ + $*font_size + """pt;
  margin-bottom: """ + ($*font_leading-$*font_size) + """pt;
}

.smallbar {
  font-size:   80%;
  font-style:  italic;
  text-align:  center;
  line-height: """ + (2*$*font_leading) + """pt;
  clear:       right;
}

.ljcomsel {
  position:     relative;
  top:          0.75pt;
  height:       7.5pt;
  padding-left: 1pt;
}
input#username, input#password { margin-right: 0.5em; }

.bs {
  margin-top:    """ + (2*$*font_leading) + """pt;
  margin-bottom: """ + (2*$*font_leading) + """pt;
  text-align:    center;
  line-height:   ${*font_leading}pt;
}

select, input, textarea {
  background-color: $*page_back;
  color:            $*entry_text;
""";
if ($*font_base != "" or $*font_fallback != "" or $*font_type != "") {
    "font-family: ";
    if ($*font_base != "") {
        "\"$*font_base\"";
        if ($*font_fallback != "" or $*font_type != "") {
            ", ";
        }
    }
    if ($*font_fallback != "") {
        "\"$*font_fallback\"";
        if ($*font_type != "") {
            ", ";
        }
    }
    if ($*font_type != "") {
        "$*font_type";
    }
    ";\n";
}
"""
  font-size:   ${*font_size}pt;
  line-height: ${*font_leading}pt;
  font-weight: normal;
}
""";
}

function find_lpar(string t) : int {
  foreach var int i (reverse (0 .. ($t->length()-1))) {
    if($t->substr($i,1)=="(") { return $i; }
  }
  return -1;
}

function render_title(string t, int len) {
  foreach var int i (0 .. ($len-1)) {
    var string pc = $t->substr($i-1,1);
    var string cc = $t->substr($i,1);
    if($cc==" ") { "$*text_seperator"; }
      elseif( $i > 0 and $pc != " ") { "$cc"; }
        elseif ($cc=="A" or $cc=="B" or $cc=="C" or $cc=="D" or $cc=="E" or $cc=="F" or $cc=="G" or $cc=="H" or $cc=="I" or $cc=="J" or $cc=="K" or $cc=="L" or $cc=="M" or $cc=="N" or $cc=="O" or $cc=="P" or $cc=="Q" or $cc=="R" or $cc=="S" or $cc=="T" or $cc=="U" or $cc=="V" or $cc=="W" or $cc=="X" or $cc=="Y" or $cc=="Z") {
          "<span class='flourish'>$cc</span>";
        }
      else { "$cc"; }
  }
}

# if we've got the voicepost player, print text using trusted function
# else, use render_body() to make pretty formatting
function print_text(EntryLite e) {
  if(not $e.text->contains("http://stat.livejournal.com/pp_play_mp3.swf")) {
    render_body($e.text);
  } else {
    $e->print_text();
  }
}

function render_body(string t) {
  var int str=0;
  var bool par=false;
  var bool pars=false;
  $str = ($t->substr(0,6) == "<br />" ? 6 : 0);
  if($t->substr(0,3) == "<p>") { $str = 3; $pars=true; }
  foreach var int i ($str .. ($t->length()-1)) {
    if($t->substr($i,12) == "<br /><br />") {
      $str=$i+12;
      if($par) { "</p><p>"; }
        else { "<p>"; $par=true; }
      }
      elseif($pars and $t->substr($i,4) == "</p>") { $str=$i+4; $pars=false; }
      elseif($i >= $str) { print $t->substr($i,1); }
  }
  if($par) { "</p>"; }
}

function display_title(Page p) {
  var string dtitle = $p.global_title;
  var string stitle = $p->view_title();
  $stitle = ($p.view == "recent" ? $p.global_subtitle : $stitle);
  var int lenm=$stitle->length()-1;
  var int i=$dtitle->length()+1;
  if ($dtitle == "") {
    $dtitle = $p.journal.name;
    $i=$dtitle->length()+1;
  }
  if ($p.view == "friends") {
    $dtitle = $p->view_title();
    $i=find_lpar($dtitle);
    if($i==-1) { $i = $lenm+2; }
  }

"""<div align="center">
<h1>"""; render_title($dtitle,$i-1); """</h1>""";
if($p.view != "friends" and $stitle != "") { """<br /><h3 style="margin-top:-1em;">$stitle</h3>"""; }
elseif($p.view == "friends" and $i<$lenm) { "<br /><h3 style='margin-top:-1em;'>" + $dtitle->substr($i+1,($lenm-$i)-1) + "</h3>"; }
"""</div>""";
}

function Page::print() {
  var string title = $this->title();

  var string links;
  var bool firstlink = true;
  foreach var string v ($.views_order) {
    if ($firstlink == false) {
      $links = "$links$*text_seperator";
    }
      else {
      $firstlink = false;
    }
    $links = $links + ("<a href='$.view_url{$v}'>"+lang_viewname($v)+"</a>");
  }

"""<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN" "http://www.w3.org/TR/html4/loose.dtd">\n<html>\n<head>\n""";

    if ($*external_stylesheet) {
        println """<link rel="stylesheet" href="$.stylesheet_url" type="text/css" />""";
    } else {
        println """<style type="text/css">"""; print_stylesheet(); "</style>";
    }
    $this->print_head();

"""<title>$title</title>
</head>
<body bgcolor="$*page_back" text="$*entry_text" link="$*page_link" vlink="$*page_vlink" alink="$*page_alink">""";
display_title($this);
"""<div style="text-align:center; margin-bottom: ${*font_leading}pt;">
<h2>$links</h2>
</div>
""";
$this->print_body();
"""
</body>
</html>
""";
}

function Entry::print_linkbar() {
  var string   link_seperator = "<br />"; # seperator for links

  # initialize array/hashes
  var string[] link_keyseq    = [""];
  var string{} link_url       = {"" => ""};
  var string{} link_caption   = {"" => ""};
  var string{} link_image     = {"" => ""};

  var string print           = "";                                         # var for printing
  var Page   p               = get_page();                                 # page handle to determine interentry
  var bool   show_interentry = ($p.view == "entry" or $p.view == "reply"); # if entry/reply view, show interentry
  var int    keyseq_index    = 0;                                          # set index point for new link_keyseq array

  if($show_interentry) {
    # if show interentry, put previous entry link first
    $link_keyseq[$keyseq_index++] = "nav_prev";

    # get previous entry link information
    var Link prev             = $this->get_link("nav_prev");
    $link_url{"nav_prev"}     = $prev.url;
    $link_caption{"nav_prev"} = $prev.caption;
    $link_image{"nav_prev"}   = $prev.icon.url;

    # get next entry link information
    var Link next             = $this->get_link("nav_next");
    $link_url{"nav_next"}     = $next.url;
    $link_caption{"nav_next"} = $next.caption;
    $link_image{"nav_next"}   = $next.icon.url;
  }

  # gather current linkbar
  foreach var string link_key ($.link_keyseq) {
    var Link  link            = $this->get_link($link_key);
    $link_url{$link_key}      = $link.url;
    $link_caption{$link_key}  = $link.caption;
    $link_image{$link_key}    = $link.icon.url;
    $link_keyseq[$keyseq_index++] = $link_key; # add this to new link_keyseq array
  }
  if($show_interentry) {
    # if show interentry, put next entry link last
    $link_keyseq[$keyseq_index++] = "nav_next";
  }

  #################################################################################################################
  # by now, the above hashes should look something like:                                                          #
  #                                                                                                               #
  # If interentry:                                                                                                #
  #   Previous Entry:                                                                                             # 
  #    $link_url{"nav_prev"}     = http://www.livejournal.com/go.bml?journal=exampleusername&itemid=256&dir=prev  #
  #    $link_caption{"nav_prev"} = Previous Entry                                                                 #
  #    $link_image{"nav_prev"}   = http://stat.livejournal.com/img/btn_prev.gif                                   #
  #                                                                                                               #
  # Edit Entry:                                                                                                   # 
  #  $link_url{"edit_entry"}     = http://www.livejournal.com/editjournal.bml?journal=exampleusername&itemid=256  #
  #  $link_caption{"edit_entry"} = Edit Entry                                                                     #
  #  $link_image{"edit_entry"}   = http://stat.livejournal.com/img/btn_edit.gif                                   #
  #                                                                                                               #
  # Edit Tags:                                                                                                    # 
  #  $link_url{"edit_tags"}      = http://www.livejournal.com/edittags.bml?journal=exampleusername&itemid=256     #
  #  $link_caption{"edit_tags"}  = Edit Tags                                                                      #
  #  $link_image{"edit_tags"}    = http://stat.livejournal.com/img/btn_edittags.gif                               #
  #                                                                                                               #
  # Add to Memories:                                                                                              # 
  #  $link_url{"mem_add"}        = http://www.livejournal.com/tools/memadd.bml?journal=exampleusername&itemid=256 #
  #  $link_caption{"mem_add"}    = Add to Memories                                                                #
  #  $link_image{"mem_add"}      = http://stat.livejournal.com/img/btn_memories.gif                               #
  #                                                                                                               #
  # If interentry:                                                                                                #
  #   Next Entry:                                                                                                 #
  #    $link_url{"nav_next"}     = http://www.livejournal.com/go.bml?journal=exampleusername&itemid=256&dir=next  #
  #    $link_caption{"nav_next"} = Next Entry                                                                     #
  #    $link_image{"nav_next"}   = http://stat.livejournal.com/img/btn_next.gif                                   #
  #################################################################################################################

  # alter data here
  $link_image{"nav_prev"}   = "";
  $link_image{"edit_entry"} = "";
  $link_image{"mem_add"}    = "";
  $link_image{"edit_tags"}  = "";
  $link_image{"nav_next"}   = "";

  # $link_keyseq[size($link_keyseq)] = "permalink";      # add a permalink to end of linkbar
  # $link_url{"permalink"}           = $.permalink_url;
  # $link_caption{"permalink"}       = $*text_permalink;
  # $link_image{"permalink"}         = "";

  $print = $link_seperator;

  # loop thru linkbar and add links to print var
  foreach var string link_key ($link_keyseq) {
    # if we can do performed action, url will be present
    if($link_url{$link_key} != "") {
      $print = $print + """<a href="$link_url{$link_key}">""";
      # if image url available, use it
      if($link_image{$link_key} != "") {
        $print = $print + """<img src="$link_image{$link_key}" alt="$link_caption{$link_key}" title="$link_caption{$link_key}" border="0" />""";
      } else {
        # else, just use text
        $print = $print + "$link_caption{$link_key}";
      }
      # add a seperator
      $print = $print + "</a>$link_seperator";
    }
  }

  # hack off last seperator
  $print = $print->substr(0, $print->length() - $link_seperator->length());

  # we're done! let's print it!
  print $print;
}

function Entry::print_metadata() {
  var string tags_header          = "Current Tags";
  var string tags_joiner          = ":";
  var Link   edit_tags            = $this->get_link("edit_tags");
  if ((size $.metadata > 0) or ((size $.tags > 0) and ($*tags_aware))){
    var string currents = "";
    $currents = """<div style="margin-top:${*font_leading}pt;"><table cellspacing="0" cellpadding="0" border="0">""";
    foreach var string k ($.metadata){
      var string text = $k;
      var string val = $.metadata{$k};
      if ($k == "mood"){
        $text = $*text_meta_mood;
      } 
      elseif ($k == "music") {
        $text = $*text_meta_music;
      }
      if ($k == "mood" and defined $.mood_icon){
        var Image i = $.mood_icon;
        $val = "<img src='$i.url' width='$i.width' height='$i.height' align='middle' alt='' /> $val";
      }
      $currents = $currents + """<tr><td align="right"><div class="sc" style="margin-right:1em;">$text</div></td><td align="left">$val</td></tr>\n""";
    }
    if ((size $.tags > 0) and $*tags_aware) {
      var int    tcount               = 0;
      if($edit_tags.url != "") {
        $tags_header = """<a href="$edit_tags.url">$tags_header</a>""";
      }
      $currents = $currents + """<tr><td align="right"><div class="sc" style="margin-right:1em;">$tags_header$tags_joiner</div></td><td align="left">""";
      foreach var Tag t ($.tags) {
        $currents = $currents + """<a rel="tag" href="$t.url">$t.name</a>""";
        $tcount++;
        if ($tcount != size $.tags) { $currents = $currents + ", "; }
      }
    }
    $currents = $currents + "</td></tr>\n</table>"; 
    println "$currents";
  }
}

function print_entry(Page p, Entry e) {
  var bool show_recent_userpic  = ($p.view == "recent")  and (true);
  var bool show_friends_userpic = ($p.view == "friends") and (true);
  var bool show_day_userpic     = ($p.view == "day")     and (true);
  var bool show_entry_userpic   = ($p.view == "entry")   and (true);
  var bool show_reply_userpic   = ($p.view == "reply")   and (true);
  var bool show_userpic         = $show_recent_userpic or $show_friends_userpic or $show_day_userpic or $show_entry_userpic or $show_reply_userpic;

  var string date=$e.time->date_format("short");
  var string time=$e.time->time_format();
  """
<table cellpadding='0' cellspacing='0' border='0' align='center'>
<tr><td align="center" colspan="2"><img
src="$*dingbar_url" alt="$*text_dingbar_alt" class="bs"/></td></tr>
<tr>
    <td align="right" valign="top" width="100"><div class="index">""";
"""        <a href="$e.permalink_url">$time<br />
        $date</a><br /><br />
    """;
    $e.comments->print();
    $e->print_linkbar();

"""    </div></td>
    <td valign="top">
        <div class="bodybox">
        <div class="author">""";

    if (defined $e.userpic and $show_userpic) {
        """<a href="$*SITEROOT/allpics.bml?user=$e.poster.username"><img border="0" src="$e.userpic.url" width="$e.userpic.width" height="$e.userpic.height" alt="$e.poster.name" title="$e.poster.name" border="0" /></a><br />""";
    }
    if ($e.poster.username != $e.journal.username and $e.journal.journal_type =="C") {
      """$e.journal<br />""";
    }
    if(($e.poster.username != $e.journal.username) or $p.view == "friends") { print $e.poster; }
    if ($e.security != "") {
        $e.security_icon->print();
    }
        
    var string subject=$e.subject;
    if($p.view=="entry") { $subject=""; }
"""</div>
        <div class="caption">
            $subject
        </div>""";
    if ($subject == "" and $p.view!="entry") {"<div class='bodyns'>";}
    elseif ($e.text->length() > $*dcLen) {"<div class='bodyl'>";}
    else {"<div class='body'>";}
    print_text($e);

    $e->print_metadata();

"""</td>
</tr>""";
"</table>";
} # print_entry(Page,Entry,Color,Color)

function Page::print_entry(Entry e) {
   print_entry($this, $e);
}

function FriendsPage::print_entry(Entry e) {
   print_entry($this, $e);
}

function RecentPage::print_body() {
  var string previous = get_plural_phrase($.nav.backward_count, "text_skiplinks_back");
  var string next     = get_plural_phrase($.nav.forward_count, "text_skiplinks_forward");
    foreach var Entry e ($.entries) {
        $this->print_entry($e);
    }
"""
<div align="center" class="bs" style="line-height: ${*font_leading}pt;"><img
src="$*dingbar_url" style="text-align:center;" alt="$*text_dingbar_alt" /></div>
<div align="center"><h2>
""";

    # go forward/backward if possible
    if ($.nav.forward_url != "" or $.nav.backward_url != "") {
        var string sep;
        var string back;
        var string forward;
        if ($.nav.backward_url != "") {
            $back = """<a href="$.nav.backward_url">$previous</a>""";
        }
        if ($.nav.forward_url != "") {
            $forward = """<a href="$.nav.forward_url">$next</a>""";
        }
        if ($back != "" and $forward != "") { $sep = "$*text_seperator"; }
        "$back$sep$forward";
    }
    "</h2></div>";
}

function CommentInfo::print() {
    if (not $.enabled) { return; }
    if ($.count > 0 or $.screened) {
        $this->print_readlink(); "<br />";
    }
    $this->print_postlink();
}

function YearPage::print_year_links() {
    """<div class="bs">
    <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
    </div><div class="sct">$*text_years_header</div><h2 style="text-align:center;">""";
    
    var bool d=false;
    foreach var YearYear y ($.years) {
        if($d) { "$*text_seperator"; }
        else { $d=true; }
        if ($y.displayed) {
            "$y.year";
        } else {
            "<a href=\"$y.url\">$y.year</a>";
        }
    }
    "</h2>";
}

function YearPage::print_month(YearMonth m) {
    if (not $m.has_entries) { return; }

 """<div class="bs">
<table cellpadding="0" cellspacing="0" border="0" summary="" align="center">
<tr><center class="noul">
<a href="$m.url">""";
        print $m->month_format();
        """</a>
<!-- now the headings for the week -->
<table align="center" cellpadding="0" cellspacing="0" border="0" summary="">
<tr align="center">
""";
    foreach var int d (weekdays()) {
        "<td align='center'>"+$*lang_dayname_short[$d]+"</td>\n";
    }
    "</tr>";
    foreach var YearWeek w ($m.weeks) {
        $w->print();
    }

    """</table></center>""";
}

function YearWeek::print() {
    "<tr valign='top'>";
    if ($.pre_empty) { "<td colspan='$.pre_empty'></td>"; }
    foreach var YearDay d ($.days) {
        """<td><div class="ywp"><div class="sfon">$d.day</div>""";
        if ($d.num_entries) {
            """<div class="uts"><a href="$d.url">$d.num_entries</a></div>""";
        } else {
            "&nbsp;";
        }
        "</div></td>";
    }
    if ($.post_empty) { "<td colspan='$.post_empty'></td>"; }
    "</tr>";
}

function DayPage::print_body() {
    if (not $.has_entries) { print "<div class='sct'>" + ehtml($*text_noentries_day) + "</div>"; }

    foreach var Entry e ($.entries) {
        $this->print_entry($e);
    }

    """<div class="bs">
    <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
    </div>""";
    var string tprev = ehtml($*text_day_prev);
    var string tnext = ehtml($*text_day_next);
    """<center><h2><a href="$.prev_url">$tprev</a>$*text_seperator<a href="$.next_url">$tnext</a></h2></center>""";

}

function MonthPage::print_body() {
    """<div class="bs">
    <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
    </div>""";
    "<center><div class='bodybox'><center><table border='0' cellspacing='0' cellpadding='0'><tr><td><dl>";
    foreach var MonthDay d ($.days) {
        if ($d.has_entries) {
            "<dt><a href=\"$d.url\"><i>";
            print lang_ordinal($d.day);
            "</i></a>:</dt>\n<dd>";
            $d->print_subjectlist();
            "</dd>\n";
        }
    }
    "</dl></td></tr></table></center></div></center>\n";
    """<div class="bs">
    <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
    </div>""";
    "<form method='post' action='$.redir.url'><center>";
    $.redir->print_hiddens();
    if ($.prev_url != "") { "<a href='$.prev_url' style='font-size:12pt;'>&#9756;</a> "; }
    if (size $.months > 1) {
        "<select name='redir_key'>\n";
        foreach var MonthEntryInfo mei ($.months) {
            var string sel;
            if ($mei.date.year == $.date.year and $mei.date.month == $.date.month) {
                $sel = " selected='selected'";
            }
            "<option value='$mei.redir_key'$sel>" + $mei.date->date_format($*lang_fmt_month_long) + "</option>";
        }
        "</select>\n<input type='submit' value='View' />";
    }
    if ($.next_url != "") { " <a href='$.next_url' style='font-size:12pt;'>&#9758;</a>\n"; }
    "</center></form>";
}

function EntryPage::print_body() {
    print_entry($this, $.entry);

    if ($.entry.comments.enabled and $.comment_pages.total_subitems > 0) {
        $.comment_pages->print();

        $this->print_multiform_start();
        "<div style='margin-top: 7pt;'></div>";
        "<table align='center' cellspacing='0' border='0' cellpadding='0' style='display: none;'><tr><td>";
        $this->print_comments($.comments);
        "</td></tr></table>";

        $.comment_pages->print();

        if ($this.multiform_on) {"""
            <div class="bs">
            <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
            </div>
            <div style="text-align: center;">""";
            $this->print_multiform_actionline();
            $this->print_multiform_end();
            "</div>";
        }
    }
}

function ItemRange::print() {
    if ($.all_subitems_displayed) { return; }
    """<div class="bs">
    <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
    </div>""";
    "<center>";
    "<a name='comments'></a><div style='width: $*body_width; text-align:center;'>";
    "<h2>" + lang_page_of_pages($.current, $.total) + "</h2>";
    var string url_prev = $this->url_of($.current - 1);
    "<table cellspacing='0' cellpadding='0' border='0' align='center'><tr><td align='center' style='font-size: 14pt'>";
    if ($.current != 1) {
        print "<a href='$url_prev#comments'>&#9756;</a>";
    } else {
        print "&#9756;";
    }
    print " </td><td align='center'>";
    foreach var int i (1..$.total) {
        if ($i == $.current) { "$i"; }
        else {
            var string url_of = $this->url_of($i);
            "<a href='$url_of#comments'>$i</a>";
        }
        if ($i != $.total) { ", "; }
    }
    "</td><td align='center' style='font-size: 14pt'> ";
    var string url_next = $this->url_of($.current + 1);
    if ($.current != $.total) {
        print "<a href='$url_next#comments'>&#9758;</a>";
    } else {
        print "&#9758;";
    }
    "</td></tr></table></div></center>";
}

function EntryPage::print_comments(Comment[] cs) {
    if (size $cs == 0) { return; }
    foreach var Comment c ($cs) {
        if($c.depth==1) {
            "</td></tr></table>";
            """<div class="bs">
              <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
            </div>""";
            "<table align='center' cellspacing='0' border='0' cellpadding='0'><tr><td>";
        }
        var int indent = ($c.depth - 1) * 21;
        "<div style='margin-left: ${indent}pt;'>\n";
        if ($c.full) {
            $this->print_comment($c);
        } else {
            $this->print_comment_partial($c);
        }
        "</div>";
        $this->print_comments($c.replies);
    }
}

function EntryPage::print_comment(Comment c) {
    var string poster = defined $c.poster ? $c.poster->as_string() : $*text_poster_anonymous;
    var string sub_icon;
    if (defined $c.subject_icon) {
        $sub_icon = $c.subject_icon->as_string();
    }
    "<a name='$c.anchor'></a>";
    "<div class='bodybox'" + ($c.depth>1? " style='margin-top:${*font_leading}pt;'" : "") + ">";
    if (defined $c.userpic and $*comment_userpic_style != "off") { 
        var int w = $c.userpic.width;
        var int h = $c.userpic.height;
        # WARNING: this will later be done by the system (it'll be a
        # constructional property), so don't copy this hack into your
        # layout layers or you'll be messed up later.
        if ($*comment_userpic_style == "small") {
            $w = $w / 2;
            $h = $h / 2;
        }
        "<img src='$c.userpic.url' width='$w' height='$h' alt='$c.poster.username' style='float: right;' class='author' />";
    }

    ### From, date, etc
    "<div class='noul'>";
    if ($c.screened) { "<span style='color:$*text_weaker;'>$*text_comment_screened </span>"; }
    "On " + $c.time->date_format("long") + ", " + $c.time->time_format() + ", $poster ";
    if ($c.metadata{"poster_ip"}) { "(" + $c.metadata{"poster_ip"} + ") "; }
    "<a href='$c.permalink_url'>";
    if ($c.depth == 1) { "$*text_comment_commented"; }
    else { "$*text_comment_replied"; }
    "</a>:</div>";

    print (defined $c.subject_icon or $c.subject != "") ? "<div class='caption'>$c.subject_icon $c.subject</div>" : "";

    "<div class='body'>";
    print_text($c);
    print "</div><div class='smallbar'>";
    if ($c.frozen) { 
        "$*text_comment_frozen";
    } else {
        "<a href='$c.reply_url'>$*text_comment_reply</a>";
    }
    if ($c.parent_url != "") { "$*text_seperator<a href='$c.parent_url'>$*text_comment_parent</a>"; }
    if ($c.thread_url != "") { "$*text_seperator<a href='$c.thread_url'>$*text_comment_thread</a>"; }
    $c->print_linkbar();
    if ($this.multiform_on) {
        "$*text_seperator";
        "<label for='ljcomsel_$c.talkid'>$*text_multiform_check</label>";
        $c->print_multiform_check();
    }
    "</div></div>";
}


function EntryPage::print_comment_partial(Comment c) {
    var string poster = defined $c.poster ? $c.poster->as_string() : $*text_poster_anonymous;
    var bool subj = $c.subject != "";
    "<div class='ult' style='width:$*body_width; margin-top:${*font_leading}pt;'>";
    "On$*text_comment_on " + $c.time->date_format("long") + ", " + $c.time->time_format() + ", $poster ";
    if ($c.metadata{"poster_ip"}) { "(" + $c.metadata{"poster_ip"} + ") "; }
    if($subj) { """$*text_comment_replied, <a href="$c.permalink_url">&ldquo;$c.subject&rdquo;</a>"""; }
    else { """posted <a href="$c.permalink_url">a reply</a>"""; }
    ".</div>";
}

function Comment::print_linkbar() {
    var Link link;
    foreach var string k ($.link_keyseq) {
        $link = $this->get_link($k);
        ($link.caption != "") ? "$*text_seperator<a href='$link.url'>$link.caption</a>" : "";
    }
}

function ReplyPage::print_body() {
    var bool ent = $.replyto.permalink_url == $.entry.permalink_url;

    if($ent) {
        print_entry($this, $.entry);
    }
    else {
        """<div class="bs">
        <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
        </div>""";
    
        var EntryLite c = $.replyto;
        var string poster = defined $c.poster ? $c.poster->as_string() : $*text_poster_anonymous;
        "<center><div style='width: $*body_width;'>";

        if (defined $c.userpic and $*comment_userpic_style != "off") { 
            var int w = $c.userpic.width;
            var int h = $c.userpic.height;
            # WARNING: this will later be done by the system (it'll be a
            # constructional property), so don't copy this hack into your
            # layout layers or you'll be messed up later.
            if ($*comment_userpic_style == "small") {
                $w = $w / 2;
                $h = $h / 2;
            }
            "<img src='$c.userpic.url' width='$w' height='$h' alt='$c.poster.name' style='float: right;' class='author' />";

        }
    
        ### From, date, etc

        "<div class='noul'>";
        "On " + $c.time->date_format("long") + ", " + $c.time->time_format() + ", $poster ";
        if ($c.metadata{"poster_ip"}) { "(" + $c.metadata{"poster_ip"} + ") "; }
        "<a href='$c.permalink_url'>$*text_comment_commented:</a></div>";
    
        print ($c.subject != "") ? "<div class='caption'>$c.subject</div>" : "";
    
        "<div class='body'>";
        print_text($c);
        "</div></div></center>";
    }

    """<div class="bs">
    <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
    </div>""";
    "<div style='text-align:center;'><h2><a href='$.entry.comments.read_url'>$*text_reply_back</a></h2></div>";
    """<div class="bs">
    <img src="$*dingbar_url" alt="$*text_dingbar_alt" />
    </div>""";

    if (not $.entry.comments.enabled) {
        print "<div class='sct'>$*text_reply_nocomments</div>";
        return;
    }


    "<center><h3 style='margin-top:0px; line-height:" + (2*$*font_leading) + "pt;'>$*text_reply_reply " + ($ent ? "$*text_reply_entry" : "$*text_reply_comment") + ":</h3>";
    $.form->print();
    "</center>";
}

tranqunzy1

kunzite1 — Mon, 04 Jul 2005 16:17:03 GMT

property declarations prettyified.
added properties for frozen comment colors.
sidebar stuffs turned into own functions.
tags list box added.
disable reply link for frozen comments.
stylesheet MUCH easier to read.
ajax comments.
added tags to Entry::print_metadata()

# LAYER INFO
layerinfo "redist_uniq" = "tranquilityii/layout";
layerinfo "type"        = "layout";
layerinfo "name"        = "Tranquility II";
layerinfo "des"         = "XHTML/CSS Compliant layout.  Relax./Heavily edited by lj:kunzite1";
layerinfo "author_name" = "Matthew Vince/Mike Trethewey";
layerinfo "lang"        = "en";

set tags_aware = true;

# PROPERTIES: COLORS
propgroup Colors {
  # odd
  property Color c_main_border {
    des = "Border color of main column";
  }
  property Color c_main_background {
  des = "Background color of main column";
  }
  property Color c_menu_border {
  des = "Border color of menu";
  }
  property Color c_header_background {
  des = "Header background color";
  }
  property Color c_header_border {
  des = "Header border color";
  }
  # page
  property Color c_page_background {
    des = "Page background color";
  }
  property Color c_page_title {
    des = "Page title color";
  }
  property Color c_page_text {
    des = "Page text color";
  }
  property Color c_page_link {
    des = "Page link color";
  }
  property Color c_page_link_visited {
    des = "Page visited link color";
  }
  property Color c_page_link_hover {
    des = "Page hover link color";
  }
  property Color c_page_link_active {
    des = "Page active link color";
  }
  # menu
  property Color c_menu_background {
    des = "Side Menu background color";
  }
  property Color c_menu_link {
    des = "Side Menu link color";
  }
  property Color c_menu_link_visited {
    des = "Side Menu visited link color";
  }
  property Color c_menu_link_hover {
    des = "Side Menu hover link color";
  }
  property Color c_menu_link_active {
    des = "Side Menu active link color";
  }
  property Color c_menu_text_color {
    des = "Side Menu text color";
  }
  property Color c_menu_header_color {
    des = "Side Menu header color";
  }
  property Color c_menu_current {
    des = "Current menu item color";
  }
  # entry
  property Color c_entry_background {
    des = "Entry background color";
  }
  property Color c_entry_link {
    des = "Entry link color";
  }
  property Color c_entry_link_visited {
    des = "Entry visited link color";
  }
  property Color c_entry_link_hover {
    des = "Entry hover link color";
  }
  property Color c_entry_link_active {
    des = "Entry active link color";
  }
  property Color c_entry_text_color {
    des = "Entry text color";
  }
  property Color c_entry_title_color {
    des = "Entry title color";
  }
  property Color c_entry_border {
    des = "Entry bottom border color";
  }
  # metadata
  property Color c_meta_background {
    des = "Entry metadata background color";
  }
  property Color c_meta_link {
    des = "Entry metadata link color";
  }
  property Color c_meta_link_visited {
    des = "Entry metadata visited link color";
  }
  property Color c_meta_link_hover {
    des = "Entry metadata hover link color";
  }
  property Color c_meta_link_active {
    des = "Entry metadata active link color";
  }
  property Color c_meta_text_color {
    des = "Entry metadata text color";
  }
  # footer
  property Color c_footer_background {
    des = "Page footer background color";
  }
  property Color c_footer_link {
    des = "Page footer link color";
  }
  property Color c_footer_link_visited {
    des = "Page footer visited link color";
  }
  property Color c_footer_link_hover {
    des = "Page footer hover link color";
  }
  property Color c_footer_link_active {
    des = "Page footer active link color";
  }
  property Color c_footer_text_color {
    des = "Page footer text color";
  }
  # comments
  property Color c_comment_one_link {
    des = "Comment one link color";
  }
  property Color c_comment_one_link_visited {
    des = "Comment one visited link color";
  }
  property Color c_comment_one_link_hover {
    des = "Comment one hover link color";
  }
  property Color c_comment_one_link_active {
    des = "Comment one active link color";
  }
  property Color c_comment_one_text_color {
    des = "Comment one text color";
  }
  property Color c_comment_one_title_color {
    des = "Comment one title color";
  }
  property Color c_comment_one_background {
    des = "Comment bar one background color";
  }
  property Color c_comment_one_border {
    des = "Comment one bottom border color";
  }
  property Color c_comment_two_link {
    des = "Comment two link color";
  }
  property Color c_comment_two_link_visited {
    des = "Comment two visited link color";
  }
  property Color c_comment_two_link_hover {
    des = "Comment two hover link color";
  }
  property Color c_comment_two_link_active {
    des = "Comment two active link color";
  }
  property Color c_comment_two_text_color {
    des = "Comment two text color";
  }
  property Color c_comment_two_title_color {
    des = "Comment two title color";
  }
  property Color c_comment_two_background {
    des = "Comment two background color";
  }
  property Color c_comment_two_border {
    des = "Comment two bottom border color";
  }
  property Color c_comment_screened_link {
    des = "Comment screened link color";
  }
  property Color c_comment_screened_link_visited {
    des = "Comment screened visited link color";
  }
  property Color c_comment_screened_link_hover {
    des = "Comment screened hover link color";
  }
  property Color c_comment_screened_link_active {
    des = "Comment screened active link color";
  }
  property Color c_comment_screened_text_color {
    des = "Comment screened text color";
  }
  property Color c_comment_screened_title_color {
    des = "Comment screened title color";
  }
  property Color c_comment_screened_background {
    des = "Comment screened background color";
  }
  property Color c_comment_screened_border {
    des = "Comment screened bottom border color";
  }
  property Color c_comment_frozen_link {
    des = "Comment frozen link color";
  }
  property Color c_comment_frozen_link_visited {
    des = "Comment frozen visited link color";
  }
  property Color c_comment_frozen_link_hover {
    des = "Comment frozen hover link color";
  }
  property Color c_comment_frozen_link_active {
    des = "Comment frozen active link color";
  }
  property Color c_comment_frozen_text_color {
    des = "Comment frozen text color";
  }
  property Color c_comment_frozen_title_color {
    des = "Comment frozen title color";
  }
  property Color c_comment_frozen_background {
    des = "Comment frozen background color";
  }
  property Color c_comment_frozen_border {
    des = "Comment frozen bottom border color";
  }
}


# PROPERTIES: FONTS
propgroup Fonts {
  # page
  property string f_page {
    des = "Generic font for use on the page";
  }
  property string f_page_size {
    des = "Generic font size for use on the page";
  }
  property string f_page_title {
    des = "Page title font";
  }
  property string f_page_title_size {
    des = "Page title font size";
  }
  property string f_page_link {
    des = "Generic font for links on the page";
  }
  property string f_page_link_size {
    des = "Generic font size for links on the page";
  }
  # menu
  property string f_menu_link {
    des = "Menu link font";
  }
  property string f_menu_link_size {
    des = "Menu link font size";
  }
  property string f_menu {
    des = "Menu font";
  }
  property string f_menu_size {
    des = "Menu font size";
  }
  property string f_menu_header {
    des = "Menu title font";
  }
  property string f_menu_header_size {
    des = "Menu title font size";
  }
  property string f_menu_current {
    des = "Current menu item font";
  }
  property string f_menu_current_size {
    des = "Current menu item font size";
  }
  # entry
  property string f_entry {
    des = "Entry font";
  }
  property string f_entry_size {
    des = "Entry font size";
  }
  property string f_entry_link {
    des = "Entry link font";
  }
  property string f_entry_link_size {
    des = "Entry link font size";
  }
  property string f_entry_title {
    des = "Entry title font";
  }
  property string f_entry_title_size {
    des = "Entry title font size";
  }
  # metadata
  property string f_meta {
    des = "Entry metadata font";
  }
  property string f_meta_size {
    des = "Entry metadata font size";
  }
  property string f_meta_link {
    des = "Entry metadata link font"; }
  property string f_meta_link_size {
    des = "Entry metadata link font size";
  }
  # footer
  property string f_footer {
    des = "Footer font";
  }
  property string f_footer_size {
    des = "Footer font size";
  }
  property string f_footer_link {
    des = "Footer link font";
  }
  property string f_footer_link_size {
    des = "Footer link font size";
  }
  # comments
  property string f_comment {
    des = "Comment font";
  }
  property string f_comment_size {
    des = "Comment font size";
  }
  property string f_comment_title {
    des = "Comment title font";
  }
  property string f_comment_title_size {
    des = "Comment title font size";
  }
  property string f_comment_link {
    des = "Comment link font";
  }
  property string f_comment_link_size {
    des = "Comment link font size";
  }
}


# PROPERTIES: PRESENTATION
propgroup Presentation {
  property use page_recent_items;
  property use page_friends_items;
  property use view_entry_disabled;
  property use use_shared_pic;
  property use comment_userpic_style;
  property bool show_recent_userpic {
    des = "Show userpic on Recent view?";
  }
  property bool show_entry_userpic {
    des = "Show userpic on Entry view?";
  }
  property bool show_day_userpic {
    des = "Show userpic on Day view?";
  }
  property bool show_entrynav_icons {
    des = "Toggle to show the next, memory, edit, etc icons on the entry view page";
  }
  property string time_format {
    des = "Format for the time";
    example = "%%hh%%:%%min%%:%%sec%% %%a%%m";
  }
  property string date_format {
    des = "Format for the date";
    example = "%%m%%/%%d%%/%%yy%%";
  }
  property bool menu_disable_userpic {
    des = "Disable menu userpic";
  }
  property bool menu_disable_navigation {
    des = "Disable menu navigation";
  }
  property bool menu_disable_summary {
    des = "Disable menu summary view";
  }
  property bool menu_disable_linklist {
    des = "Disable menu linklist";
  }
  property bool menu_disable_tag_list {
    des = "Disable menu tag list";
  }
  property string tags_sidebar_height {
    des = "Height of Tags sidebar box";
  }
  property string css_page_width {
    des = "Width of the main page (increasing this will increase the main column's width)";
  }
  property string css_style_overrides {
    des = "include any CSS here to override the default CSS";
  }
}


# PROPERTIES: TEXT
propgroup Text {
  property use text_post_comment;
  property use text_read_comments;
  property use text_post_comment_friends;
  property use text_read_comments_friends;
  property use text_meta_music;
  property use text_meta_mood;
  property string text_meta_tags_header {
    des = "Text for Tags header";
    example = "Tags";
  }
  property string text_meta_tags_joiner {
    des = "Text for Tags joiner";
    example = ":";
  }
  property use text_permalink;
  property use text_view_recent;
  property use text_view_friends;
  property use text_view_archive;
  property use text_view_userinfo;
  property use text_reply_nocomments_header;
  property use text_reply_nocomments;
  property use text_comment_from;
  property use text_comment_ipaddr;
  property use text_comment_parent;
  property use text_comment_reply;
  property use text_comment_thread;
  property use text_nosubject;
  property use text_post_comment;
  property use text_post_comment_friends;
  property use text_max_comments;
  property use text_view_month;
  property use text_poster_anonymous;
  property string text_comment_viewall {
    des = "Text for view all comments";
  }
  property string text_links_header {
    des = "Sidebar links header text";
  }
  property string text_summary_header {
    des = "Page summary text header";
  }
  property string text_links_spacer {
    des = "String to act as links list spacer";
  }
}


# -------------------------------
# default property settings
# -------------------------------
# ODD
set c_comment_one_background        = "#ffffff";
set c_comment_one_border            = "#999999";
set c_comment_one_link              = "#5ab300";
set c_comment_one_link_active       = "#336600";
set c_comment_one_link_hover        = "#336600";
set c_comment_one_link_visited      = "#5ab300";
set c_comment_one_text_color        = "#333333";
set c_comment_one_title_color       = "#333333";
set c_comment_frozen_background     = "#aaaaff";
set c_comment_frozen_border         = "#999999";
set c_comment_frozen_text_color     = "#333333";
set c_comment_frozen_title_color    = "#333333";
set c_comment_frozen_link           = "#eeeeff";
set c_comment_frozen_link_visited   = "#eeeeff";
set c_comment_frozen_link_hover     = "#eeeeff";
set c_comment_frozen_link_active    = "#eeeeff";
set c_comment_screened_background   = "#ffaaaa";
set c_comment_screened_border       = "#999999";
set c_comment_screened_link         = "#ffeeee";
set c_comment_screened_link_active  = "#ffeeee";
set c_comment_screened_link_hover   = "#ffeeee";
set c_comment_screened_link_visited = "#ffeeee";
set c_comment_screened_text_color   = "#000000";
set c_comment_screened_title_color  = "#000000";
set c_comment_two_background        = "#ffffff";
set c_comment_two_border            = "#999999";
set c_comment_two_link              = "#5ab300";
set c_comment_two_link_active       = "#336600";
set c_comment_two_link_hover        = "#336600";
set c_comment_two_link_visited      = "#5ab300";
set c_comment_two_text_color        = "#333333";
set c_comment_two_title_color       = "#333333";
set c_entry_background              = "#ffffff";
set c_entry_border                  = "#cccccc";
set c_entry_link                    = "#5ab300";
set c_entry_link_active             = "#336600";
set c_entry_link_hover              = "#336600";
set c_entry_link_visited            = "#5ab300";
set c_entry_text_color              = "#333333";
set c_entry_title_color             = "#333333";
set c_footer_background             = "#333333";
set c_footer_link                   = "#ffffff";
set c_footer_link_active            = "#ffffff";
set c_footer_link_hover             = "#ffffff";
set c_footer_link_visited           = "#ffffff";
set c_footer_text_color             = "#ffffff";
set c_header_background             = "#333333";
set c_header_border                 = "#333333";
set c_main_background               = "#ffffff";
set c_main_border                   = "#000000";
set c_menu_background               = "#333333";
set c_menu_border                   = "#333333";
set c_menu_current                  = "#ffffff";
set c_menu_header_color             = "#ffffff";
set c_menu_link                     = "#999999";
set c_menu_link_active              = "#ffffff";
set c_menu_link_hover               = "#ffffff";
set c_menu_link_visited             = "#999999";
set c_menu_text_color               = "#ffffff";
set c_meta_background               = "#ffffff";
set c_meta_link                     = "#5ab300";
set c_meta_link_active              = "#336600";
set c_meta_link_hover               = "#336600";
set c_meta_link_visited             = "#5ab300";
set c_meta_text_color               = "#000000";
set c_page_background               = "#333333";
set c_page_link                     = "#5ab300";
set c_page_link_active              = "#336600";
set c_page_link_hover               = "#336600";
set c_page_link_visited             = "#5ab300";
set c_page_text                     = "#333333";
set c_page_title                    = "#ffffff";
# FONTS
set f_comment            = "Georgia, serif";
set f_comment_link       = "Georgia, serif";
set f_comment_link_size  = "100%";
set f_comment_size       = "100%";
set f_comment_title      = "Georgia, serif";
set f_comment_title_size = "130%";
set f_entry              = "Georgia, serif";
set f_entry_link         = "Georgia, serif";
set f_entry_link_size    = "100%";
set f_entry_size         = "100%";
set f_entry_title        = "Georgia, serif";
set f_entry_title_size   = "150%";
set f_footer             = "Georgia, serif";
set f_footer_link        = "Georgia, serif";
set f_footer_link_size   = "100%";
set f_footer_size        = "100%";
set f_menu               = "Georgia, serif";
set f_menu_current       = "Verdana, Helvetica, sans-serif";
set f_menu_current_size  = "80%";
set f_menu_header        = "Georgia, serif";
set f_menu_header_size   = "120%";
set f_menu_link          = "Verdana, Helvetica, sans-serif";
set f_menu_link_size     = "80%";
set f_menu_size          = "100%";
set f_meta               = "Verdana, Helvetica, sans-serif";
set f_meta_link          = "Verdana, Helvetica, sans-serif";
set f_meta_link_size     = "100%";
set f_meta_size          = "80%";
set f_page               = "Georgia, serif";
set f_page_link          = "Georgia, serif";
set f_page_link_size     = "100%";
set f_page_size          = "12px";
set f_page_title         = "Georgia, serif";
set f_page_title_size    = "190%";

# OTHER
set show_recent_userpic     = false;
set show_day_userpic        = true;
set show_entry_userpic      = true;
set show_entrynav_icons     = true;
set time_format             = "%%hh%%:%%min%% %%a%%m";
set date_format             = "%%mon%%. %%dayord%%, %%yyyy%%";
set menu_disable_userpic    = false;
set menu_disable_navigation = false;
set menu_disable_summary    = false;
set menu_disable_linklist   = false;
set menu_disable_tag_list   = false;
set tags_sidebar_height     = "";
set css_style_overrides     = "";
set css_page_width          = "800px";

# TEXT
set text_meta_music            = "music";
set text_links_header          = "links";
set text_meta_mood             = "mood";
set text_meta_tags_header      = "tags";
set text_meta_tags_joiner      = ":";
set text_read_comments         = "{#}";
set text_read_comments_friends = "{#}";
set text_poster_anonymous     = "anonymous";
set text_comment_viewall       = "view all comments";
set text_links_header          = "Links";
set text_summary_header        = "Page Summary";
set text_links_spacer          = "_______________";



# ========================================
# METHODS
# ========================================


# -------------------------------
# stylesheet
# -------------------------------
function print_stylesheet() {
"""
@media screen, print {
  * {
    margin:  0;
    padding: 0;
  }
  hr {
    display: none;
  }
  body {
    background-color: $*c_page_background;
    font-family:      $*f_page;
    font-size:        $*f_page_size;
    line-height:      125%;
    color:            $*c_page_text;
    text-align:       center;
  }
  a {
    font-family:     $*f_page_link;
    font-size:       $*f_page_link_size;
    color:           $*c_page_link;
    text-decoration: none;
  }
  a:visited { color: $*c_page_link_visited; }
  a:hover, a:visited:hover { color: $*c_page_link_hover; text-decoration: underline; }
  a:active { color: $*c_page_link_active; }
  a img { border: none; }
  p {
    margin:  5px;
    padding: 5px;
  }
  form {
    display: inline;
    margin:  0px;
    padding: 0px;
  }
  input, select, textarea {
    font-family: $*f_meta;
    font-size:   $*f_meta_size;
    color:       $*c_meta_text_color;
    padding:     2px;
    margin:      3px;
  }
  #container {
    position:   relative;
    width:      $*css_page_width;
    margin:     0 auto;
    text-align: left;
  }
  #header {
    margin-bottom:    15px;
    border:            1px solid $*c_header_border;
    background-color: $*c_header_background;
  }
  #header h1 {
    padding:     20px;
    font-family: $*f_page_title;
    font-size:   $*f_page_title_size;
    color:       $*c_page_title;
  }
  #menu {
    position:         relative;
    background-color: $*c_menu_background;
    float:            left;
    width:            150px;
    font-family:      $*f_menu;
    font-size:        $*f_menu_size;
    color:            $*c_menu_text_color;
    border:           1px solid $*c_menu_border;
    padding:          4px;
  }
  #content {
    position:    relative;
    margin-left: 160px;
  }
  #entries {
    border:            1px solid $*c_main_border;
    padding:          15px;
    background-color: $*c_main_background;
  }
  #menu h2 {
    margin:      20px 0;
    font-family: $*f_menu_header;
    font-size:   $*f_menu_header_size;
    color:       $*c_menu_header_color;
  }
  #menu h2.userpic {
    text-align: center;
  }
  #menu a {
    font-family: $*f_menu_link;
    font-size:   $*f_menu_link_size;
    color:       $*c_menu_link;
  }
  #menu a:visited { color: $*c_menu_link_visited; }
  #menu a:hover, #menu a:visited:hover { color: $*c_menu_link_hover; }
  #menu a:active { color: $*c_menu_link_active; }
  #menu ul {
    margin:     3px;
    list-style: none;
  }
  #menu ul li {
    margin:     3px;
    padding:    2px;
    list-style: none;
  }
  #menu ul li.active {
    font-family: $*f_menu_current;
    font-size:   $*f_menu_current_size;
    color:       $*c_menu_current;
    font-weight: bold;
  }
  #content h2 {
    margin: 20px 0;
  }
  #entries, #comments {
    margin: 10px;
  }
  .ind-entry {
    padding: 5px;
    padding-bottom:   15px;
    border-bottom:     1px solid $*c_entry_border;
    background-color: $*c_entry_background;
  }
  .ind-entry h3 img, .ind-comment-one h3 img, .ind-comment-two h3 img, .ind-comment-screened h3 img {
    position: relative;
    float:    right;
    padding:  5px;
  }
  .ind-entry h2 {
    font-family: $*f_entry_title;
    font-size:   $*f_entry_title_size;
    color:       $*c_entry_title_color;
    margin:      20px 0px;
    line-height: 140%;
  }
  .ind-entry h4, .ind-comment-one h4, .ind-comment-two h4, .ind-comment-screened h4 {
    font-family: $*f_meta;
    font-size:   $*f_meta_size;
    color:       $*c_meta_text_color;
  }
  .ind-entry h4 {
    background-color: $*c_meta_background;
  }
  .ind-entry h4 a, .ind-comment-one h4 a, .ind-comment-two h4 a, .ind-comment-screened h4 a {
    font-family:     $*f_meta_link;
    font-size:       $*f_meta_link_size;
    color:           $*c_meta_link;
    text-decoration: underline;
  }
  .ind-entry h4 a:visited, .ind-comment-one h4 a:visited, .ind-comment-two h4 a:visited, .ind-comment-screened h4 a:visited { color: $*c_meta_link_visited; }
  .ind-entry h4 a:hover, .ind-comment-one h4 a:hover, .ind-comment-two h4 a:hover, .ind-comment-screened h4 a:hover { color: $*c_meta_link_hover; }
  .ind-entry h4 a:visited:hover, .ind-comment-one h4 a:visited:hover, .ind-comment-two h4 a:visited:hover, .ind-comment-screened h4 a:visited:hover { color: $*c_meta_link_hover; }
  .ind-entry h4 a:active, .ind-comment-one h4 a:active, .ind-comment-two h4 a:active, .ind-comment-screened h4 a:active { color: $*c_meta_link_active; }
  .ind-entry div.entry-item, .ind-entry div.month-entries {
    font-family: $*f_entry;
    font-size:   $*f_entry_size;
    color:       $*c_entry_text_color;
    margin:      15px 0px;
  }
  .ind-entry div.entry-item a, .ind-entry div.month-entries a {
    font-family:     $*f_entry_link;
    font-size:       $*f_entry_link_size;
    color:           $*c_entry_link;
    text-decoration: underline;
  }
  .ind-entry div.entry-item a:visited, .ind-entry div.month-entries a:visited { color: $*c_entry_link_visited; }
  .ind-entry div.entry-item a:hover, .ind-entry div.entry-item a:visited:hover { color: $*c_entry_link_hover; }
  .ind-entry div.month-entries a:hover, .ind-entry div.month-entries a:visited:hover { color: $*c_entry_link_hover; }
  .ind-entry div.entry-item a:active, .ind-entry div.month-entries a:active { color: $*c_entry_link_active; }
  .ind-comment-one, .ind-comment-two, .ind-comment-screened {
    margin:  10px 0;
    padding:  5px;
  }
  .ind-comment-one { background-color: $*c_comment_one_background; border-bottom: 1px solid $*c_comment_one_border; }
  .ind-comment-two { background-color: $*c_comment_two_background; border-bottom: 1px solid $*c_comment_two_border; }
  .ind-comment-screened { background-color: $*c_comment_screened_background; border-bottom: 1px solid $*c_comment_screened_border; }
  .ind-comment-one h2 {
    font-family: $*f_comment_title;
    font-size:   $*f_comment_title_size;
    color:       $*c_comment_one_title_color;
    margin:      20px 0px;
  }
  .ind-comment-one div.entry-item {
    font-family: $*f_comment;
    font-size:   $*f_comment_size;
    color:       $*c_comment_one_text_color;
    margin:      15px 0px;
  }
  .ind-comment-one div.entry-item a {
    font-family:     $*f_comment_link;
    font-size:       $*f_comment_link_size;
    color:           $*c_comment_one_link;
    text-decoration: underline;
  }
  .ind-comment-one div.entry-item a:visited { color: $*c_comment_one_link_visited; }
  .ind-comment-one div.entry-item a:hover, .ind-comment-one div.entry-item a:visited:hover { color: $*c_comment_one_link_hover; }
  .ind-comment-one div.entry-item a:active { color: $*c_comment_one_link_active; }
  .ind-comment-two h2 {
    font-family: $*f_comment_title;
    font-size:   $*f_comment_title_size;
    color:       $*c_comment_two_title_color;
    margin:      20px 0px;
    line-height: 140%;
  }
  .ind-comment-two div.entry-item {
    font-family: $*f_comment;
    font-size:   $*f_comment_size;
    color:       $*c_comment_two_text_color;
    margin:      10px 0px;
  }
  .ind-comment-two div.entry-item a {
    font-family:     $*f_comment_link;
    font-size:       $*f_comment_link_size;
    color:           $*c_comment_two_link;
    text-decoration: underline;
  }
  .ind-comment-two div.entry-item a:visited { color: $*c_comment_two_link_visited; }
  .ind-comment-two div.entry-item a:hover, .ind-comment-two div.entry-item a:visited:hover { color: $*c_comment_two_link_hover; }
  .ind-comment-two div.entry-item a:active { color: $*c_comment_two_link_active; }
  .ind-comment-screened h2 {
    font-family: $*f_comment_title;
    font-size:   $*f_comment_title_size;
    color:       $*c_comment_screened_title_color;
    margin:      20px 0px;
  }
  .ind-comment-screened div.entry-item {
    font-family: $*f_comment;
    font-size:   $*f_comment_size;
    color:       $*c_comment_screened_text_color;
    margin:      10px 0px;
  }
  .ind-comment-screened div.entry-item a {
    font-family:     $*f_comment_link;
    font-size:       $*f_comment_link_size;
    color:           $*c_comment_screened_link;
    text-decoration: underline;
  }
  .ind-comment-screened div.entry-item a:visited { color: $*c_comment_screened_link_visited; }
  .ind-comment-screened div.entry-item a:hover, .ind-comment-screened div.entry-item a:visited:hover { color: $*c_comment_screened_link_hover; }
  .ind-comment-screened div.entry-item a:active { color: $*c_comment_screened_link_active; }

.ind-comment-screened h3 img {
  position: relative;
  float:    right;
  padding:  5px;
}
.ind-comment-screened h4 {
  font-family: $*f_meta;
  font-size:   $*f_meta_size;
  color:       $*c_comment_screened_text_color;
}
.ind-comment-screened h4 a {
  font-family:     $*f_meta_link;
  font-size:       $*f_meta_link_size;
  color:           $*c_comment_screened_link;
  text-decoration: underline;
}
.ind-comment-screened h4 a:visited {
  color: $*c_comment_screened_link_visited;
}
.ind-comment-screened h4 a:hover {
  color: $*c_comment_screened_link_hover;
}
.ind-comment-screened h4 a:visited:hover {
  color: $*c_comment_screened_link_hover;
}
.ind-comment-screened h4 a:active {
  color: $*c_comment_screened_link_active;
}
.ind-comment-screened {
  margin:  10px 0;
  padding: 5px;
}
.ind-comment-screened {
  background-color: $*c_comment_screened_background;
  border-bottom:    1px solid $*c_comment_screened_border;
}
.ind-comment-screened h2 {
  font-family: $*f_comment_title;
  font-size:   $*f_comment_title_size;
  color:       $*c_comment_screened_title_color;
  margin:      20px 0px;
}
.ind-comment-screened div.entry-item {
  font-family: $*f_comment;
  font-size:   $*f_comment_size;
  color:       $*c_comment_screened_text_color;
  margin:      10px 0px;
}
.ind-comment-screened div.entry-item a {
  font-family:     $*f_comment_link;
  font-size:       $*f_comment_link_size;
  color:           $*c_comment_screened_link;
  text-decoration: underline;
}
.ind-comment-screened div.entry-item a:visited {
  color: $*c_comment_screened_link_visited;
}
.ind-comment-screened div.entry-item a:hover, .ind-comment-screened div.entry-item a:visited:hover {
  color: $*c_comment_screened_link_hover;
}
.ind-comment-screened div.entry-item a:active {
  color: $*c_comment_screened_link_active;
}
.ind-comment-frozen h3 img {
  position: relative;
  float:    right;
  padding:  5px;
}
.ind-comment-frozen h4 {
  font-family: $*f_meta;
  font-size:   $*f_meta_size;
  color:       $*c_comment_frozen_text_color;
}
.ind-comment-frozen h4 a {
  font-family:     $*f_meta_link;
  font-size:       $*f_meta_link_size;
  color:           $*c_comment_frozen_link;
  text-decoration: underline;
}
.ind-comment-frozen h4 a:visited {
  color: $*c_comment_frozen_link_visited;
}
.ind-comment-frozen h4 a:hover {
  color: $*c_comment_frozen_link_hover;
}
.ind-comment-frozen h4 a:visited:hover {
  color: $*c_comment_frozen_link_hover;
}
.ind-comment-frozen h4 a:active {
  color: $*c_comment_frozen_link_active;
}
.ind-comment-frozen {
  margin:  10px 0;
  padding: 5px;
}
.ind-comment-frozen {
  background-color: $*c_comment_frozen_background;
  border-bottom:    1px solid $*c_comment_frozen_border;
}
.ind-comment-frozen h2 {
  font-family: $*f_comment_title;
  font-size:   $*f_comment_title_size;
  color:       $*c_comment_frozen_title_color;
  margin:      20px 0px;
}
.ind-comment-frozen div.entry-item {
  font-family: $*f_comment;
  font-size:   $*f_comment_size;
  color:       $*c_comment_frozen_text_color;
  margin:      10px 0px;
}
.ind-comment-frozen div.entry-item a {
  font-family:     $*f_comment_link;
  font-size:       $*f_comment_link_size;
  color:           $*c_comment_frozen_link;
  text-decoration: underline;
}
.ind-comment-frozen div.entry-item a:visited {
  color: $*c_comment_frozen_link_visited;
}
.ind-comment-frozen div.entry-item a:hover, .ind-comment-frozen div.entry-item a:visited:hover {
  color: $*c_comment_frozen_link_hover;
}
.ind-comment-frozen div.entry-item a:active {
  color: $*c_comment_frozen_link_active;
}
#postform, #commenttext {
  width: 90%;
}

  .month-entries {
    margin: 10px 0;
  }
  .month-entries ul {
    list-style: none;
    margin:     10px;
  }
  .month-entries ul li {
    list-style: none;
    padding: 3px;
  }
  #footer {
    position: relative;
    font-family:      $*f_footer;
    font-size:        $*f_footer_size;
    color:            $*c_footer_text_color;
    background-color: $*c_footer_background;
  }
  #footer p {
    padding: 20px;
  }
  #footer a {
    font-family: $*f_footer_link;
    font-size:   $*f_footer_link_size;
    color:       $*c_footer_link;
  }
  #footer a:visited { color: $*c_footer_link_visited; }
  #footer a:hover, #footer a:visited:hover { color: $*c_footer_link_hover; }
  #footer a:active { color: $*c_footer_link_active; }
}

@media print {
  #menu {
    display: none;
  }
  #content {
    margin-left: 0px;
  }
  #entries, .ind-entry, .ind-comment, #footer, #header {
    border: none;
  }
}

$*css_style_overrides

""";
}

function print_sidebar_box(string class, string header, string content) {
  if($header != "") {
    "<h2"; if($class != "") { " class=\"$class\""; } ">";
    print safe $header;
    "</h2>";
  }
  if($content != "") {
    print safe $content;
  }
  "<hr />";
}

function print_sidebar_box(string header, string content) {
  print_sidebar_box("", $header, $content);
}

# -------------------------------
# user pic main page
# -------------------------------
function Page::lay_top_userpic() {
  var Image up_img = $.journal.default_pic;
  if ( defined $up_img ) {
    print_sidebar_box( "userpic", "<a href=\"$*SITEROOT/allpics.bml?user=$.journal.username\"><img border=\"0\" src=\"$up_img.url\" height=\"$up_img.height\" width=\"$up_img.width\" alt=\"$.journal.name\" /></a>", "" );
  }
}


# -------------------------------
# returns a permalink link based on
# the url passed
# -------------------------------
function get_permalink ( string url ) : string {	
  return("<a href=\"$url\" title=\"permalink\" class=\"$*text_permalink\">$*text_permalink</a>");
}


# -------------------------------
# prints the user's 'link-list'
# -------------------------------
function Page::print_linklist() {
  var string header  = "";
  var string content = "";
  if ( size $.linklist > 0 ) {
    $header  = $*text_links_header;
    $content = $content + "<ul id=\"user-links\">";
    foreach var UserLink l ( $.linklist ) {
      if ( $l.title == "spacer" ) {
        $content = $content + "<li>$*text_links_spacer</li>";
      } elseif ($l.is_heading) {
        $content = $content + "<li><b>$l.title</b></li>";
      } elseif ( $l.title ) {
        $content = $content + "<li><a href=\"$l.url\" title=\"$l.title\">$l.title</a></li>";
      }
    }
    $content = $content + "</ul>";
    print_sidebar_box($header, $content);
  }
}


# -------------------------------
# prints the LJ specific links (recent, friends, etc)
# -------------------------------
function print_lj_links ( Page p ) {
  var string links;
  var string[] views_order = $p.views_order; # view order
                                                                           # "recent"   = recent   view
                                                                           # "friends"  = friends  view
                                                                           # "archive"  = calendar view
                                                                           # "userinfo" = userinfo link
  var string{} view_text   = { # build text hash
                              "recent"   => $*text_view_recent,
                              "friends"  => $p.journal_type != "C" ? $*text_view_friends : $*text_view_friends_comm,
                              "archive"  => $*text_view_archive,
                              "userinfo" => $*text_view_userinfo
                             };
  var string   base_url    = $p.journal->base_url(); # get base url
  var string{} view_url    = { # build url hash
                              "recent"   => "$base_url/",
                              "friends"  => "$base_url/friends/",
                              "archive"  => "$base_url/calendar/",
                              "userinfo" => "$*SITEROOT/userinfo.bml?user=$p.journal.username&mode=full"
                             };
  foreach var string v ($views_order) {
    $links = $links + """<li><a href="$view_url{$v}">$view_text{$v}</a></li>""";
  }
  if($p.journal.website_url != "") {
    $links = $links + """<li><a href="$p.journal.website_url">""" + ($p.journal.website_name != "" ? $p.journal.website_name : $*text_website_default_name) + """</a></li>""";
  }
  $links = "<ul id=\"lj-links\">" + $links + "</ul>";
  print_sidebar_box("", $links);
}

function Page::lay_sidebar_view_summary() : string {
  return("");
}

function print_tag_list(Page p) {
  var string header  = "";
  var string content = "";
  var Tag[] tags = $p->visible_tag_list();
  if(size $tags) {
    $header = "$*text_meta_tags_header$*text_meta_tags_joiner";
    var string height = $*tags_sidebar_height;
    if($height != "") {
      $content = $content + """<div style="position:relative; height:$height; overflow: auto;">""";
    }
    $content = $content + "<ul>";
    foreach var Tag tag ($tags) {
      $content = $content + """<li><a href="$tag.url">$tag.name</a></li>""";
    }
    $content = $content + "</ul>";
    if($height != "") {
      $content = $content + "</div>";
    }
    print_sidebar_box($header, $content);
  }
}

function print_sidebar(Page p) {
  # print userpic
  if(not $*menu_disable_userpic) {
    $p->lay_top_userpic();
  }

  if(not $*menu_disable_navigation) {
    # print navigation
    print_lj_links($p);
  }

  # print summary
  print($p->lay_sidebar_view_summary());

  if(not $*menu_disable_linklist) {
    # print linklist
    $p->print_linklist();
  }
              
  if(not $*menu_disable_tag_list) {
    # print tag list
    print_tag_list($p);
  }
}

# -------------------------------
# main page layout
# -------------------------------
function Page::print() {
  var string title = $this->title();

  # generate page id:
  var string current_view = $.view;
  if ( $.view == "month" or $.view == "day" ) {
    $current_view = "archive";	
  }
  if ( $.view == "entry" or $.view == "reply" ) {
    $current_view = "recent";	
  }

  # begin main page html:
  print "<!DOCTYPE html PUBLIC \"-//W3C//DTD XHTML 1.0 Transitional//EN\" \"http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd\">\n";
  print "<html xmlns=\"http://www.w3.org/1999/xhtml\" lang=\"\">\n";
    print "<head>\n";
      print "<meta name=\"resource-type\" content=\"Document\" />\n";
      print "<meta name=\"type\" content=\"index\" />\n";
      print "<link rel=\"stylesheet\" type=\"text/css\" href=\"$.stylesheet_url\" />\n";
      $this->print_head();
      print "<link rel=\"bookmark\" href=\"#header\" title=\"Top of the Page\" />\n";
      print "<link rel=\"bookmark\" href=\"#menu\" title=\"Main Menu\" />\n";
      print "<link rel=\"bookmark\" href=\"#summary\" title=\"Page Summary\" />\n";
      print "<link rel=\"bookmark\" href=\"#content\" title=\"Entries\" />\n";
      print "<title>$title</title>\n";
    print "</head>\n";
    print "<body id=\"$current_view\">\n";
      print "<div id=\"container\">\n";
        print "<div id=\"header\">\n";
          print "<div id=\"banner\">\n";
            print "<h1>$title</h1>\n";
            print "<hr />";
          print "</div>\n";
        print "</div>\n";
        print "<div id=\"menu\">\n";
          print_sidebar($this);
        print "</div>\n";
        print "<div id=\"content\">\n";
          $this->print_body();
        print "</div>\n";
      print "</div>\n";
    print "</body>\n";
  print "</html>\n";
}

# -------------------------------
# main page display entries and
# footer
# -------------------------------
function RecentPage::print_body() {
  # print all entries
  print "<div id=\"entries\">\n";
  foreach var Entry e ( $.entries ) {
    $this->print_entry($e);
  }
  print "</div>";

  var string range = "most recent entries";
  if ( $.nav.skip > 0 ) {
    $range = "$.nav.skip entries back";
  }

  print "<div id=\"footer\"><p>";
  print "<b>viewing:</b> $range<br />";
  # go forward/backward if possible
  if ( $.nav.forward_url != "" or $.nav.backward_url != "" ) {
    var string sep;
    var string back;
    var string forward;
    if ( $.nav.backward_url != "" ) {
      $back = "<a href=\"$.nav.backward_url\" title=\"go earlier\">earlier</a>";
    }
    if ( $.nav.forward_url != "" ) {
      $forward = "<a href=\"$.nav.forward_url\" title=\"go later\">later</a>";
    }
    if ( $back != "" and $forward != "" ) { 
      $sep = " | ";
    }
    print "<b>go</b>: $back$sep$forward<br />";
  }
  print "</p></div>";
}


# -------------------------------
# entry view (show comments)
# -------------------------------
function EntryPage::print_body() {
  print "<div id=\"entries\">\n";
    $this->print_entry ( $.entry );
    if ( $.entry.comments.enabled ) {
      print "<h2>Comments {$.entry.comments.count}</h2>";
      print "<div id=\"comments\">";
        if ( $.comment_pages.total_subitems > 0 ) {
          if ( $this.multiform_on ) {
            $this->print_multiform_start();
          }
          $.comment_pages->print();
          set_handler("unscreen_comment_#", [
                                             [ "style_bgcolor", "cmtbar#", "$*c_comment_one_background",      ],
                                             [ "style_color",   "cmtbar#", "$*c_comment_one_text_color",      ],
                                            ]);
          set_handler("screen_comment_#",   [
                                             [ "style_bgcolor", "cmtbar#", "$*c_comment_screened_background", ],
                                             [ "style_color",   "cmtbar#", "$*c_comment_screened_text_color", ],
                                            ]);
          set_handler("unfreeze_comment_#", [
                                             [ "style_bgcolor", "cmtbar#", "$*c_comment_one_background",      ],
                                             [ "style_color",   "cmtbar#", "$*c_comment_one_text_color",      ],
                                            ]);
          set_handler("freeze_comment_#",   [
                                             [ "style_bgcolor", "cmtbar#", "$*c_comment_frozen_background", ],
                                             [ "style_color",   "cmtbar#", "$*c_comment_frozen_text_color",      ],
                                            ]);
          $this->print_comments($.comments);
          if ( $this.multiform_on ) {
            $this->print_multiform_actionline();
            $this->print_multiform_end();
          }
        }
      print "</div>";
    }
  print "</div>";
  print "<div id=\"footer\"><p>";
    print "<a href=\"$.entry.comments.post_url\" title=\"$*text_post_comment\">$*text_post_comment</a>\n";
  print "</p></div>";	
}

# -------------------------------
# day view
# -------------------------------
function DayPage::print_body() {
  if ( not $.has_entries ) {
    print "<div id=\"entries\">\n";
    print "<div class=\"ind-entry\">\n";
    print "<h2>" + $.date->date_format("long") + "</h2>";
    print "<p>$*text_noentries_day</p>";
    print "</div>";
    print "</div>";
    print "<hr />";
  } else {
    print "<div id=\"entries\">\n";
    foreach var Entry e ( $.entries ) {
      $this->print_entry($e);
    }
    print "</div>";
  }

  var string tprev = ehtml($*text_day_prev);
  var string tnext = ehtml($*text_day_next);

  print "<div id=\"footer\"><p>";
  print "<a href=\"$.prev_url\" title=\"laquo; $tprev\">&laquo; $*text_day_prev</a> | <a href=\"$.next_url\" title=\"$tnext &raquo;\">$*text_day_next &raquo;</a>";
  print "</p></div>";
}


# -------------------------------
# year view
# -------------------------------
function YearPage::print_body() {
  print "<div id=\"entries\">\n";
  $this->print_year_links();
  foreach var YearMonth m ($.months) {
    $this->print_month($m);
  }
  print "</div>";
}


# -------------------------------
# page summary for recent page
# -------------------------------
function RecentPage::lay_sidebar_view_summary() : string {
  var string return;
  if ( not $*menu_disable_summary ) {
    foreach var Entry e ( $.entries ) {
      $return = $return + "<li>$e.security_icon <a href=\"#$e.journal.username$e.itemid\">" + ($e.subject != "" ? "$e.subject" : "$*text_nosubject") + "</a> [<a href=\"$e.permalink_url\">" + (($e.comments.count > 0) ? $e.comments.count + "" : "#") + "</a>]</li>";
    }
  }
  if ( $return != "" ) {
    $return = "<h2>$*text_summary_header</h2><ul id=\"lj-summary\">" + $return + "</ul><hr />"; 
  }
  return($return);
}


# -------------------------------
# page summary for day page
# -------------------------------
function DayPage::lay_sidebar_view_summary() : string {
  var string return;
  if ( not $*menu_disable_summary ) {
    foreach var Entry e ( $.entries ) {
      $return = $return + "<li>$e.security_icon <a href=\"#$e.journal.username$e.itemid\">" + ($e.subject != "" ? "$e.subject" : "$*text_nosubject") + "</a> [<a href=\"$e.permalink_url\">" + (($e.comments.count > 0) ? $e.comments.count + "" : "#") + "</a>]</li>";
    }
  }
  if ( $return != "" ) {
    $return = "<h2>$*text_summary_header</h2><ul id=\"lj-summary\">" + $return + "</ul><hr />"; 
  }
  return($return);
}


# -------------------------------
# page summary for entry page
# -------------------------------
function EntryPage::lay_sidebar_view_summary() : string {
  var string return;
  if ( not $*menu_disable_summary ) {
    foreach var Comment c ( $.comments ) {
      if ( $c.depth == 1 ) {
        $return = $return + "<li><a href=\"#c.anchor\">" + ($c.subject != "" ? "$c.subject" : "$*text_nosubject") + "</a> [<a href=\"$c.permalink_url\">#</a>]</li>";	
      }
    }
  }
  if ( $return != "" ) {
    $return = "<h2>$*text_summary_header</h2><ul id=\"lj-summary\">" + $return + "</ul><hr />"; 
  }
  return($return);
}


function Entry::print_metadata() {
  var string tags_header          = $*text_meta_tags_header;
  var string tags_joiner          = $*text_meta_tags_joiner;
  var Link   edit_tags            = $this->get_link("edit_tags");
  if ((size $.metadata > 0) or ((size $.tags > 0) and ($*tags_aware))){
    var string currents = "";
    $currents = """<div class="currents">""";
    foreach var string k ($.metadata){
      var string text = $k;
      var string val = $.metadata{$k};
      if ($k == "mood"){
        $text = $*text_meta_mood;
      } 
      elseif ($k == "music") {
        $text = $*text_meta_music;
      }
      if ($k == "mood" and defined $.mood_icon){
        var Image i = $.mood_icon;
        $val = "<img src='$i.url' width='$i.width' height='$i.height' align='middle' alt='' /> $val";
      }
      $currents = $currents + """<div class="current$k"><strong>$text:</strong> $val</div>""";        
    }
    if ((size $.tags > 0) and $*tags_aware) {
      var int    tcount               = 0;
      if($edit_tags.url != "") {
        $tags_header = """<a href="$edit_tags.url">$tags_header</a>""";
      }
      $currents = $currents + """<span class="tags_header">$tags_header$tags_joiner</span> """;
      foreach var Tag t ($.tags) {
        $currents = $currents + """<a rel="tag" href="$t.url">$t.name</a>""";
        $tcount++;
        if ($tcount != size $.tags) { $currents = $currents + ", "; }
      }
    }
    $currents = $currents + "</div>"; 
    println "$currents";
  }
}

# -------------------------------
# display an entry (all views )
# -------------------------------
function print_entry ( Page p, Entry e ) {
  # get date/time
  var string datetime;
  $datetime = $e.time->date_format($*date_format) + " | " + $e.time->time_format($*time_format);

  # get any extra user info (if posting to community, etc)
  var string poster = "";
  var string userpic = "";
  if ( $p.view == "friends" or $p.journal_type == "C" or $e.poster.username != $e.journal.username ) {
    if ( $e.poster.username != $e.journal.username ) {
      $poster = "$e.poster in $e.journal";
    } else {
      $poster =  $e.poster->as_string();
    }
    $poster = "<b>posted by:</b> $poster";
  }
  if ( defined $e.userpic and ( ($p.view == "recent" and $*show_recent_userpic) or ($p.view == "day" and $*show_day_userpic) or ($p.view == "entry" and $*show_entry_userpic) or ($p.view == "friends") ) ) {
    $userpic = """<h3 class="userpic"><a href="$*SITEROOT/allpics.bml?user=$e.poster.username" target="_blank"><img border="0" src="$e.userpic.url" width="$e.userpic.width" height="$e.userpic.height" alt="$e.poster.username's user pictures" title="$e.poster.username's user pictures" /></a></h3>""";
  }

  # print the entry now:
  print "<div id=\"$e.journal.username$e.itemid\" class=\"ind-entry\">";

    # print icon (if needed)
    if ( $userpic != "" ) {
      print "$userpic";	
    }

    print "<h2>";
      if ( $e.security != "" ) {
        $e.security_icon->print();
        print " ";
      }
      if ( $e.subject == "" ) {
        print "<i>$*text_nosubject</i>";
      } else {
        print "$e.subject";
      }
    print "</h2>";

    print "<h4>";
      if ( $p.view == "entry" and $*show_entrynav_icons ) {
        var string item_link = "";
        foreach var string key (["nav_prev","nav_next"]) {
          var Link link = $e->get_link($key);
          if ( $link ) { 
            if ( $key == "nav_prev" ) {
              $item_link = $item_link + "<a href=\"$link.url\" title=\"" + $link.caption->lower() + "\">&laquo; " + $link.caption->lower() + "</a> | ";
            } elseif ( $key == "nav_next" ) {
              $item_link = $item_link + "<a href=\"$link.url\" title=\"" + $link.caption->lower() + "\">" + $link.caption->lower() + " &raquo;</a>";
            }
          }
        }
        print $item_link;
        print "<br />";
      }
      print "<b>$datetime</b><br />";
      $e->print_metadata();
      if ( $poster != "" ) {
        print "$poster";	
      }
    print "</h4>";

    print "<div class=\"entry-item\">"; $e->print_text(); "</div>\n";

    print "<h4>";
#		print get_permalink($e.permalink_url);
      if ( $p.view != "entry" and $p.view != "reply" ) {
#			print " | ";
        $e.comments->print();
      } elseif ( $e.comments.enabled ) {
#			print " | ";
        $e.comments->print_postlink();
      }
      var Link tmp;
      var string[] link_keyseq = $e.link_keyseq;
      foreach var string key ($link_keyseq) {
        $tmp = $e->get_link($key);
        if($tmp.caption != "" and $tmp.url != "") {
          print """ | <a href="$tmp.url" title="$tmp.caption">$tmp.caption</a>""";
        }
      }
      print """ | <a href="$e.permalink_url" title="$*text_permalink">$*text_permalink</a>""";
    print "</h4>";
  print "</div>";
  print "<hr />";
}


# -------------------------------
# entry wrapper for main page
# -------------------------------
function Page::print_entry(Entry e) {
  print_entry($this, $e);
}


# -------------------------------
# entry wrapper for friends page
# -------------------------------
function FriendsPage::print_entry(Entry e) {
   print_entry($this, $e);
}


function EntryPage::print_entry(Entry e) {
  print_entry($this, $e);
}


# -------------------------------
# comments
# -------------------------------
function CommentInfo::print() {
  if ( not $.enabled ) {
    return;
  }

  $this->print_postlink();
  if ( $.count > 0 or $.screened ) {
    print " ";
    print "<b>";
    $this->print_readlink();
    print "</b>";
  }
}


# -------------------------------
# comment post link
# -------------------------------
function CommentInfo::print_postlink() {
  var Page p = get_page();
  var string linktext = ( $p.view == "friends" ? $*text_post_comment_friends : $*text_post_comment );
  if ( $.maxcomments ) {
    "$*text_max_comments";
  } else {
    "<a href=\"$.post_url\" title=\"$linktext\" class=\"comments\">$linktext</a>";
  }
}


# -------------------------------
# print comment
# -------------------------------
function EntryPage::print_comment(Comment c) {
  var string comment_class = "";   
  if ( $c.screened ) {
    $comment_class = "ind-comment-screened";
  } elseif ( $c.frozen ) {
    $comment_class = "ind-comment-frozen";
  } elseif ( $c.depth % 2 == 0 ) {
    $comment_class = "ind-comment-two";
  } else {
    $comment_class = "ind-comment-one";
  }

  var string poster = defined $c.poster ? $c.poster->as_string() : "<i>$*text_poster_anonymous</i>";
  var string poster_text = defined $c.poster ? $c.poster.name : "<i>$*text_poster_anonymous</i>";
  var string sub_icon;
  var int indent = (($c.depth - 1) * 5);
  if ( defined $c.subject_icon ) {
    $sub_icon = $c.subject_icon->as_string();
  }

  print "<div class=\"$comment_class\" id=\"cmtbar$c.talkid\" style=\"margin-left: ${indent}px;\">\n";

    var string userpic;
    if ( defined $c.userpic and $*comment_userpic_style != "off" ) {
      $userpic = """<h3 class="userpic"><a href="$*SITEROOT/allpics.bml?user=$c.poster.username" target="_blank"><img border="0" src="$c.userpic.url" width="$c.userpic.width" height="$c.userpic.height" alt="$c.poster.username's user pictures" title="$c.poster.username's user pictures" /></a></h3>""";
    }
    var string commentdate = "";
    $commentdate = $c.time->date_format($*date_format) + " - " + $c.time->time_format($*time_format);

    #userpic
    print "$userpic\n";

    # subject:
    if ( $c.subject == "" ) {
      print "<h2 name=\"$c.anchor\" id=\"$c.anchor\">$c.subject_icon <i>$*text_nosubject</i></h2>";
    } else {
      print "<h2 name=\"$c.anchor\" id=\"$c.anchor\">$c.subject_icon $c.subject</h2>";
    }

    print "<h4>";
      print "<b>$*text_comment_from</b> $poster<br />\n";
      print "<b>$*text_comment_date</b> $commentdate<br />\n";
      if ( $c.metadata{"poster_ip"} ) {
        print "<b>$*text_comment_ipaddr</b> " + $c.metadata{"poster_ip"} + "<br />";
      }
      print get_permalink($c.permalink_url) + "<br />\n";
      var Link lnk;
      foreach var string key ($c.link_keyseq) {
        $lnk = $c->get_link($key); 
        if ( $lnk.url != "" ) { if($lnk.icon.url != "") { print """<a href="$lnk.url"><img src="$lnk.icon.url" width="$lnk.icon.width" height="$lnk.icon.height" alt="$lnk.caption" title="$lnk.caption" border="0" /></a> """; } }
      }
    print "</h4>\n";

    if ( $this.multiform_on ) {
      print "<label for=\"ljcomsel_$c.talkid\">$*text_multiform_check</label>";
      $c->print_multiform_check();
    }

    print "<div class=\"entry-item\">"; $c->print_text(); "</div>\n";
    print "<h4>";
      if ( not $c.frozen       ) { print "<a href=\"$c.reply_url\" title=\"$*text_comment_reply\">$*text_comment_reply</a>";       } else { print $*text_comment_frozen; }
      if ( $c.parent_url != "" ) { print " | <a href=\"$c.parent_url\" title=\"$*text_comment_parent\">$*text_comment_parent</a>"; }
      if ( $c.thread_url != "" ) { print " | <a href=\"$c.thread_url\" title=\"$*text_comment_thread\">$*text_comment_thread</a>"; }
    print "</h4>";
  print "</div>\n\n";
  print "<hr />";
}

function EntryPage::print_comment_partial (Comment c) {
  var string poster = defined $c.poster ? $c.poster->as_string() : "<i>$*text_poster_anonymous</i>";
  var string subj = $c.subject != "" ? $c.subject : $*text_nosubject;
  print """<a href="$c.permalink_url" name="$c.anchor" id="$c.anchor">$subj</a> - $poster""";
}

# -------------------------------
# print reply form page
# -------------------------------
function ReplyPage::print_body() {
  if ( not $.entry.comments.enabled ) {
    print "<div id=\"entries\">\n";
      print "<div class=\"ind-entry\">";
        print "<h2>$*text_reply_nocomments_header</h2>";
        print "$*text_reply_nocomments";
      print "</div>";
    print "</div>";
  } else {
    print "<div id=\"entries\">\n";

      # get date
      var string datetime;
      $datetime = $.replyto.time->date_format($*date_format) + " | " + $.replyto.time->time_format($*time_format);

      # get any extra user info (if posting to community, etc)
      var string poster = "";
      var string userpic = "";
      if ( defined $.replyto.poster ) {
        $poster = $.replyto.poster->as_string();
        if ( defined $.replyto.userpic ) {
          $userpic = """<h3 class="userpic"><a href="$*SITEROOT/allpics.bml?user=$.replyto.poster.username" target="_blank"><img border="0" src="$.replyto.userpic.url" width="$.replyto.userpic.width" height="$.replyto.userpic.height" alt="$.replyto.poster.username's user pictures" title="$.replyto.poster.username's user pictures" /></a></h3>""";
        }
      } else {
        $poster = "<i>$*text_poster_anonymous</i>";
      }

      # print the entry now:
      print "<div class=\"ind-entry\">";
        # print icon (if needed)
        if ( $userpic != "" ) {
          print "$userpic";	
        }
        print "<h2>";
          if ( $.replyto.subject == "" ) {
            print "<i>$*text_nosubject</i>";
          } else {
            print "$.replyto.subject";
          }
        print "</h2>";

        print "<h4>\n";
          print "<b>$datetime</b><br />";
          print "<b>$*text_comment_from</b> $poster";
          if ( $.replyto.metadata{"poster_ip"} ) {
            print "<b>$*text_comment_ipaddr</b> " + $.replyto.metadata{"poster_ip"} + "<br />";
          }
        print "</h4>";
        print "<div class=\"entry-item\">"; $.replyto->print_text(); "</div>\n";
        print "<h4>";
          print get_permalink($.replyto.permalink_url) + " | <a href=\"$.entry.comments.read_url\" title=\"$*text_comment_viewall\">$*text_comment_viewall</a>\n";
        print "</h4>";
      print "</div>\n";
      print "<hr />";
      print "<div class=\"entry-form\">\n";
        print "<h2>Reply</h2>\n";
        $.form->print();
      print "</div>";
    print "</div>";
  }
}

# -------------------------------
# print available years
# -------------------------------
function YearPage::print_year_links() {
  print "<h4>";
    print "<b>available years:</b><br />";
    foreach var YearYear y ($.years) {
      if ($y.displayed) {
        print "<b>$y.year</b> ";
      } else {
        print "<a href=\"$y.url\" title=\"$y.year\">$y.year</a> ";
      }
    }
  print "</h4>";
}


# -------------------------------
# print available month
# -------------------------------
function YearPage::print_month ( YearMonth m ) {
  if ( not $m.has_entries ) { 
    return;
  }

  print "<div class=\"ind-entry\">\n";
    print "<h2>" + $m->month_format() + "</h2>\n";
    print "<h4><a href=\"$m.url\" title=\"$*text_view_month\">$*text_view_month</a></h4>";
    print "<div style=\"month\">";
      foreach var YearWeek w ( $m.weeks ) {
        foreach var YearDay d ( $w.days ) {
          if ( $d.num_entries > 0 ) {
            var string date = $d.date->date_format("%%dayord%%");
            print "<b>$date</b> {<a href=\"$d.url\" title=\"d.num_entries comments\">$d.num_entries</a>}<br />\n";
          }
        }
      }
      print "</div>\n";
    print "</div>\n";
  print "<hr />";
}


# -------------------------------
# month view
# -------------------------------
function MonthPage::print_body() {
  print "<div id=\"entries\">";
    print "<div class=\"ind-entry\">\n";
      print "<h2>" + $.date->date_format($*lang_fmt_month_long) + "</h2>";

      print "<form method=\"post\" action=\"$.redir.url\">";
        $.redir->print_hiddens();
        if ( $.prev_url != "" ) { 
          print "[<a href=\"$.prev_url\" title=\"&laquo;\">&laquo;</a>]\n";
        }
        if ( size $.months > 1 ) {
          print "<select name=\"redir_key\">\n";
            foreach var MonthEntryInfo mei ( $.months ) {
              var string sel;
              if ( $mei.date.year == $.date.year and $mei.date.month == $.date.month ) {
                $sel = " selected=\"selected\"";
              }
              print "<option value=\"$mei.redir_key\" label=\"" + $mei.date->date_format($*lang_fmt_month_long) + "\" $sel>" + $mei.date->date_format($*lang_fmt_month_long) + "</option>";
            }
          print "</select>\n<input type=\"submit\" value=\"View\" />";
        }
        if ( $.next_url != "" ) { 
          print "\n[<a href=\"$.next_url\" title=\"&raquo;\">&raquo;</a>]\n";
        }
      print "</form><br /><br />";

      # print dates:
      foreach var MonthDay d ( $.days ) {
        if ( $d.has_entries ) {
          print "<div class=\"month-entries\">\n";
            print "<a href=\"$d.url\" title=\"" + lang_ordinal($d.day) + "\"><b>" + lang_ordinal($d.day) + "</b></a><br />";
            print "<ul>";
              foreach var Entry e ( $d.entries ) {
                print "<li>";
                  print "" + $e.time->time_format("short") + " ";
                  if ( $e.poster.username != $e.journal.username ) {
                    $e.poster->print(); " : ";
                  }
                  "$e.security_icon ";
                  if ( $e.subject == "" ) {
                    print "<a href=\"$e.permalink_url\" title=\"$*text_nosubject\"><i>$*text_nosubject</i></a>";
                  } else {
                    print "<a href=\"$e.permalink_url\" title=\"$e.subject\">$e.subject</a>";
                  }
                  if ( $e.comments.count > 0 ) {
                    print " {" + $e.comments.count + "}";
                  }
                  print "</li>";
                }
            print "</ul>";
          print "</div>";
          print "<hr />";
        }
      }
    print "</div>\n";
  print "</div>";
}

3kunumn1

kunzite1 — Sun, 03 Jul 2005 17:00:52 GMT

changes:
property declarations prettyified.
stylesheet MUCH easier to read.
<div>s for sidebars changed to table cells.
commented out images that don't work right.
hard coded text for images that don't work right.
added tags to Entry::print_metadata()
fixed header image
k1-ified Entry::print_linkbar() and added image toggle for links
image toggle for comment links
new text properties for edit entry, add to mem, edit tags, tell friend text

todo:
ajax comments
quick reply comments

layerinfo "type"            = "layout";
layerinfo "name"            = "3 column";
layerinfo "author_name"     = "Louise (unfloopy)/Kunzite (kunzite1)";
layerinfo "author_email"    = "unfloopy@gmail.com/kunzite1@livejournal.com";
layerinfo "des"             = "3 column layout by Louise (/~unfloopy)./Edited greatly by Kunzite (/~kunzite1)";
layerinfo "redist_uniq"     = "3column/layout";
layerinfo "source_viewable" = 1;

################################## PROPERTIES ####################################

propgroup prez = "Presentation";
propgroup prez {
  property bool show_entry_userpic {
    des = "Always display userpic?";
  }
  property bool color_forms {
    des  = "Form Elements";
    note = "Select No to disable the customized form elements.";
  }
  property bool image_links {
    des  = "Use Images for comment links";
  }
  property use  use_shared_pic;
  property use  view_entry_disabled;
  property use  page_recent_items;
  property use  page_friends_items;
  property use  tags_aware;

  set show_entry_userpic = true;
  set color_forms        = true;
  set image_links        = true;
  set page_recent_items  = 10;
  set page_friends_items = 20;
  set tags_aware         = true;
}

propgroup text = "Text";
propgroup text {
  property use text_skiplinks_forward;
  property use text_skiplinks_back;
  property use text_post_comment;
  property use text_reply_back;
  property use text_permalink;
  property string t_divider {
    des = "Entries Navigation: Links divider";
  }
  property string t_edit_entry {
    des = "Text used for Edit Entry link/caption";
  }
  property string t_mem_add {
    des = "Text used for Add to Memories link/caption";
  }
  property string t_edit_tags {
    des = "Text used for Edit Tags link/caption";
  }
  property string t_tell_friend {
    des = "Text used for Tell a Friend link/caption";
  }
  property use text_comment_reply;
  property use text_read_comments;
  property use text_view_recent;
  property use text_view_archive;
  property use text_view_userinfo;
  property use text_view_friends;
  property use text_nosubject;
  property use text_noentries_day;
  property use text_meta_music;
  property use text_meta_mood;
  property use text_view_month;
  property use text_read_comments_friends;
  property string links_header {
    des = "Links header";
  }
  property string about_title {
    des = "About box title";
  }
  property string nav_title {
    des = "Navigation title";
  }
  property string blurb_title {
    des = "Blurb Title";
  }
  property string blurb_text {
    des = "Blurb Text";
  }

  set text_skiplinks_forward     = "forward >";
  set text_skiplinks_back        = "< back";
  set text_post_comment          = "reply";
  set text_reply_back            = "comments";
  set text_permalink             = "link";
  set t_divider                  = " ";	
  set t_edit_entry               = "edit entry";
  set t_mem_add                  = "mem";
  set t_edit_tags                = "edit tags";
  set t_tell_friend              = "tell friend";
  set text_comment_reply         = "reply";
  set text_read_comments         = "#";
  set text_view_recent           = "recent";
  set text_view_archive          = "archive";
  set text_view_userinfo         = "userinfo";
  set text_view_friends          = "friends";
  set text_nosubject             = "nothing";
  set text_noentries_day         = "I didn't post on this day. Sorry!";
  set text_meta_music            = "current song:";
  set text_meta_mood             = "current mood:";
  set text_view_month            = "view all";
  set text_read_comments_friends = "#";
  set links_header               = "links";
  set about_title                = "about";
  set nav_title                  = "navigate";
  set blurb_title                = "blurb";
  set blurb_text                 = "you can write here about anything you want.";
}	

propgroup images = "Images";
propgroup images {
  property string bg_image {
    des = "Background Image URL [optional]";
  }
  property string bg_repeat {
    des = "Background Image Repeat [either repeat or no-repeat]";
  }
  property string header_image {
    des = "Header: Image URL [optional]";
  }
  property string header_height {
    des = "Header: Height [a must IF you have a header image]";
  }
  property string i_comment {
    des = "Icon: Comments";
  }
  property string i_perma {
    des = "Icon: PermaLink";
  }
  property string i_mem {
    des = "Icon: Add To Memories";
  }
  property string i_leave {
    des = "Icon: Leave A Comment";
  }
  property string i_edit {
    des = "Icon: Edit Entry";
  }
  property string i_tags {
    des = "Icon: Edit Tags";
  }

  set bg_image      = "";
  set bg_repeat     = "repeat";
  set header_image  = "";
  set header_height = "0px";
  set i_comment     = "";
  set i_perma       = "";
  set i_mem         = "";
  set i_leave       = "";
  set i_edit        = "";
  set i_tags        = "";
}

propgroup stylesheet = "Stylesheet";
propgroup stylesheet {
  property string font_size {
    des = "Overall: Font Size";
  }
  property string font_family {
    des = "Overall: Font Family";
  }
  property string link_weight {
    des = "Overall: Link Weight [either normal or bold]";
  }
  property string link_side_w {
    des = "Sidebar: Link weight [normal or bold]";
  }
  property string side_h_size {
    des = "Sidebar: Header Size";
  }
  property string entries_size {
    des = "Entries: Font Size";
  }
  property string sub_size {
    des = "Entries: Subject Text Size";
  }
  property string c_sub_size {
    des = "Comments: Subject Text Size";
  }

  set font_size    =  "8pt";
  set font_family  = "arial";
  set link_weight  = "normal";
  set link_side_w  = "normal";
  set entries_size =  "9pt";
  set c_sub_size   = "10pt";
  set side_h_size  = "13px";
  set sub_size     = "15pt";
}

propgroup colors = "Color";
propgroup colors {
  property Color color_bg {
    des = "Background Color";
  }
  property Color font_color {
    des = "Overall: Font Color";
  }
  property Color link_color {
    des = "Overall: Link Color";
  }
  property Color link_hover {
    des = "Overall: Link Hover Color";
  }
  property Color link_side {
    des = "Sidebar: Link color";
  }
  property Color link_side_h {
    des = "Sidebar: Link hover color";
  }
  property Color side_bg {
    des = "Sidebar: Background color";
  }
  property Color side_t_color {
    des = "Sidebar: Text color";
  }
  property Color side_border {
    des = "Sidebar: Borders";
  }
  property Color side_h_color {
    des = "Sidebar: Header Color";
  }
  property Color side_h_border {
    des = "Sidebar: Header Border";
  }
  property Color side_h_bg {
    des = "Sidebar: Header Background";
  }
  property Color entries_bg {
    des = "Entries: Background color";
  }
  property Color entries_border {
    des = "Entries: Border color";
  }
  property Color button_bg {
    des = "Entries: Buttons background";
  }
  property Color button_bg_h {
    des = "Entries: Buttons Background hover";
  }
  property Color entries_font_color {
    des = "Entries: Font Color";
  }
  property Color sub_color {
    des = "Entries: Subject Color";
  }
  property Color c_sub_color {
    des = "Comments: Subject Text Color";
  }
  property Color c_sub_bg {
    des = "Comments: Subject Background";
  }

  set color_bg           = "#e6cabe";
  set font_color         = "#4b3730";
  set link_color         = "#78534b";
  set link_hover         = "#78534b";
  set link_side          = "#4b3730";
  set link_side_h        = "#4b3730";
  set side_bg            = "#e6cabe";
  set side_t_color       = "#4b3730";
  set side_border        = "#dab5ac";
  set side_h_color       = "#333333";
  set side_h_border      = "#333333";
  set side_h_bg          = "#dab5ac";
  set entries_bg         = "#e6cabe";
  set entries_border     = "#dab5ac";
  set button_bg          = "#e6cabe";
  set button_bg_h        = "#ecd7c7";
  set entries_font_color = "#4b3730";
  set sub_color          = "#78534b";
  set c_sub_color        = "#4b3730";
  set c_sub_bg           = "#dab5ac";
}


####################################### STYLESHEET #######################################

function print_stylesheet ()  {"""
body {
  background: $*color_bg;
  font:       $*font_size $*font_family;
  color:      $*font_color; 
""";
if (clean_url($*bg_image) != "") {
  """  background-image:  url($*bg_image);
  background-repeat: $*bg_repeat;
  """; } """}
a {
  color:       $*link_color;
  font-weight: $*link_weight;
}
a:hover {
  color:       $*link_hover;
  font-weight: $*link_weight;
}
.currenttags a {
  font-weight: bold;
}
h1 {
  color:         $*sub_color;
  font-size:     $*sub_size;
  text-align:    left;
  padding:       5px;
  margin:        0px;
  border-bottom: 1px dashed $*entries_border;
}
h2 {
  border:           1px solid $*side_h_border;
  font-size:        $*side_h_size;
  text-align:       center;
  margin:           3px 0px;
  padding:          0px;
  background-color: $*side_h_bg;
  color:            $*side_h_color;
}
h3 {
  color:      $*sub_color;
  text-align: left;
  font:       bold arial;
  padding:    5px;
  margin:     0px;
  border-top: solid 1px $*entries_border;
}
ul.links {
  margin:          1px 0px;
  padding:         3px;
  color:           $*side_t_color;
  list-style-type: none;
}
li.links {
  margin-left: 5px;
}
li.links a {
  text-decoration: none;
}
li.links_header {
  font:          11px;
  border-bottom:  1px solid $*side_t_color;
  padding-top:    7px;
}
""";
if($*color_forms) {
"""
select, input, textarea {
  background-color: $*entries_bg;
  color:            $*font_color;
}
""";
}
"""
#container{
/*  position: absolute;
  top:      $*header_height; */
}
#leftbar{
/*  position: absolute;
  top:       10px;
  left:      10px; */
  width:    170px;
}
#rightbar{
/*  position: absolute;
  top:       10px;
  right:      0px; */
  width:    170px;
}
#leftbar a, #rightbar a {
  color:       $*link_side;
  font-weight: $*link_side_w;
}
#leftbar a:hover, #rightbar a:hover {
  color: $*link_side_h;
}
#entries{
  margin:     10px 0px 10px 0px;
  text-align: center;
  background: $*entries_bg;
  border:      3px double $*entries_border;
  padding:    10px;
}
#readme {
  text-align: justify;
  padding:    2px;
}
#header {
position: absolute;
width:    100%;
top:      0px;
left:     0px;
height:   $*header_height;
"""; if (clean_url($*header_image) != "") {
  """  background-image:  url($*header_image);
  background-repeat: no-repeat;
  background-align:  center;
"""; } """ }

div.entrylinks {
  font:           8pt Verdana;
  text-align:    right;
  padding:        2px 10px 2px 10px;
  line-height:   20px;
  margin-bottom:  0px;
  margin-top:     5px;
  border-top:     1px dashed $*entries_border;
}
div.entrylinks a {
  background-color: $*button_bg;
  text-decoration:  none;
  margin:           2px;
  padding:          2px;
}
div.entrylinks a:hover {
  background-color: $*button_bg_h;
}
div.entrylinks img {
  border:          0px;
  text-decoration: none;
}
div.entry{
  margin-bottom: 35px;
}

.entrytext{
  font:       $*entries_size Arial;
  text-align: justify;
  color:      $*entries_font_color;
}
.aboutentry{
  text-align:   left;
  margin-right: 10px;
}
.userpic{
  margin: 5px;
}
.sidebox{
  border:      3px double $*side_border;
  background: $*side_bg;
  margin:     10px;
  padding:     5px;
}
.userpic2{
  position: relative;
  float:    left;
  padding:  5px;
  margin:   0px 0px 0px 0px;
}
.userpic_reply{
  position: relative;
  float:    left;
  padding:  5px;
}
.moodpic{
  position:     relative;
  float:        right;
  padding:        0px;
  padding-left:   5px;
  margin:         0px;
  margin-top:   -10px;
  margin-right:  -5px;
}
.calendarActive{
  font-weight: bold;
}
.blurb {
  color: $*side_t_color;
}
.nosubject {
  font-style: italic;
}
.replyform {
  text-align: left;
}
.comment_postedby {
  text-align:  left;
  font-weight: bold;
}
.comment_date{
  text-align: left;
}
.comment_subject {
  color:          $*c_sub_color;
  background:     $*c_sub_bg;
  font:           $*c_sub_size;
  font-weight:    bold;
  letter-spacing: 1.5px;
  text-align:     left;
  padding:        3px;
  margin-right:   0;
}
.comment_wrapper{
  border:     1px solid $*entries_border;
  background: $*entries_bg;
  padding:    5px;
  margin:     0px 0px 5px 0px;
}
.comment_info {
  width: 95%;
}
.comment_links {
  text-align: right;
  padding:    3px;
  margin:     0px;
  border-top: 1px dashed $*entries_border;
}
.comment_links a {
  padding:         2px;
  text-decoration: none;
}
.comment_child {
  margin: 0px 0px 0px 20px;
}
.minicomment {
  padding: 4px;
  border:  1px solid $*entries_border;
}
.minicommentholder {
  border: 1px solid $*entries_border;
}
"""; }

############################# FUNCTIONS ########################################

function prop_init() {
  if ($*i_comment == "") { $*i_comment = "$*IMGDIR/style/3column/comments.gif"; }
  if ($*i_perma == "")   { $*i_perma   = "$*IMGDIR/style/3column/permalink.gif"; }
  if ($*i_mem == "")     { $*i_mem     = "$*IMGDIR/style/3column/memories.gif"; }
  if ($*i_leave == "")   { $*i_leave   = "$*IMGDIR/style/3column/leavecomment.gif"; }
  if ($*i_edit == "")    { $*i_edit    = "$*IMGDIR/style/3column/editentry.gif"; }
  if ($*i_tags == "")    { $*i_tags    = "$*IMGDIR/style/3column/edittags.gif"; }
}

function replace_text(string text, string find, string replacement) : string "Search within \$text and replaces any occurences of \$find with \$replacement." {
#######################################################
# from lj:mageboltrat's industrial nippon (id=533012) #
#######################################################
  var string[] findarray;
  var int pos = 1;
  foreach var string findcharacter($find) {
    $findarray[$pos] = $findcharacter;
    $pos             = $pos + 1;
  }
  var int    place         = 1;
  var bool   found         = false;
  var string completedtext = "";
  var string foundtext     = "";
  foreach var string searchcharacter($text) {
    if  ($searchcharacter == $findarray[$place]) {
      if ($place == $find->length()) {
        $foundtext =  $replacement;
        $place     = 1;
      } else {
        $foundtext = $foundtext + $searchcharacter;
        $place     = $place + 1;
      }  
    } else {
      $completedtext = $completedtext + $foundtext + $searchcharacter;
      $foundtext     = "";  
      $place         = 1;    
    }
  }
  $completedtext = $completedtext + $foundtext;
  return $completedtext;
}

function rehtml(string text) : string "Unescape html in \$text by replacing &gt; with > and &lt; with <." {
####################################################################
# by lj:masterslacker using lj:mageboltrat's replace_text function #
####################################################################
  return replace_text(replace_text(replace_text(replace_text($text, "&lt;", "<"), "&gt;", ">"), "&amp;lt;", "<"), "&amp;gt;", ">");
}

function generateDots (string un)  : string {
  var string dots;
  if($un != "") {
    foreach var string s ($un)  {
      if($s == "a" or $s == "c" or $s == "e" or $s == "f" or $s == "h" or $s == "k" or $s == "m" or $s == "n" or $s == "p" or $s == "r" or $s == "t" or $s == "v" or $s == "x" or $s == "z") {
        $dots = $dots + ":";
      } elseif($s == " ") {
        $dots = $dots + " ";
      } else {
        $dots = $dots + ".";
      }
    }
  }
  return $dots;
}

function print_linkbox (string header, string text)  {
  """<div class="sidebox">\n""";
  print safe "<h2>$header</h2>\n";
  print safe """<ul class="links">\n$text\n</ul>\n""";
  "</div>\n";
}

function box_item (string text) : string {
  return "$text\n";
}

function print_box (string header, string text) {
  """<div class="sidebox">""";
  print safe """<h2>$header</h2>""";
  print safe "$text\n";
  "</div>";
}

function Page::lay_print_userpic() : string {
  var string return = "";
  if(defined $.journal.default_pic) {
    $return = """<div id="userpic"><a href="$*SITEROOT/allpics.bml?user=$.journal.username"><img src="$.journal.default_pic.url" width="$.journal.default_pic.width" height="$.journal.default_pic.height" alt="$.journal.name" title="$.journal.name" border="0" /></a></div>""";
  }
  return $return;
}

function Page::lay_print_calendar ()  {
  var YearMonth m    = $this->get_latest_month();
  var string    mon  = $m->month_format();
  var string    text = "";
  $text = """<table cellspacing="2" cellpadding="2" border="0" width="100%">""";
  foreach var YearWeek w ($m.weeks) {
    $text = $text + """<tr>""";
    if($w.pre_empty > 0) {
      foreach var int empty (1..$w.pre_empty)  {
        $text = $text + """<td class="calempty">&nbsp;</td>""";
      }
    }
    foreach var YearDay d ($w.days) {
      if($d.num_entries > 0) {
        $text = $text + """<td class="calendarActive"><a href="$d.url">$d.day</a></td>""";
      } else {
        $text = $text + """<td class="calendarInactive">$d.day</td>""";
      }
    }
    $text = $text + "</tr>\n";
  }
  $text = $text + "</table>";
  print_box($mon, $text);
}

function print_left_bar() {
  var Page   p       = get_page();
  var string header  = "";
  var string content = "";
  """
        <td id="leftbar" valign="top">
          <div>
  """;

  $header  = $*about_title;
  $content = """<div align="center">""" + $p->lay_print_userpic() + "<br />" + $p.journal->as_string() + "<br />" + """<a href="$*SITEROOT/friends/add.bml?user=$p.journal.username"><img src="$*IMGDIR/btn_addfriend.gif" alt="Friend Me" title="Friend Me" width="22" height="20" style="border: 0;" /></a> <a href="$*SITEROOT/todo/?user=$p.journal.username"><img src="$*IMGDIR/btn_todo.gif" alt="My To-do List" title="My To-do List" width="22" height="20" style="border: 0;" /></a> <a href="$*SITEROOT/tools/memories.bml?user=$p.journal.username"><img src="$*IMGDIR/btn_memories.gif" alt="Memories" title="Memories" width="22" height="20" style="border: 0;" /></a></div>""";
  print_box($header, $content);

  if($*blurb_text != "") {
    $header  = $*blurb_title;
    $content = rehtml($*blurb_text);
    print_box($header, $content);
  }

  $p->lay_print_calendar();
  """
          </div>
        </td>
  """;
}

function print_right_bar() {
  var Page   p       = get_page();
  var string header  = "";
  var string content = "";
  """
        <td id="rightbar" valign="top">
          <div>
  """;

  $header  = $*nav_title;
  $content = """<ul class="links">""";
  var string[] views_order = ["recent", "friends", "archive", "userinfo"]; # view order
                                                                           # "recent"   = recent   view
                                                                           # "friends"  = friends  view
                                                                           # "archive"  = calendar view
                                                                           # "userinfo" = userinfo link
  var string{} view_text   = { # build text hash
                              "recent"   => $*text_view_recent,
                              "friends"  => $p.journal_type != "C" ? $*text_view_friends : $*text_view_friends_comm,
                              "archive"  => $*text_view_archive,
                              "userinfo" => $*text_view_userinfo
                             };
  var string   base_url    = $p.journal->base_url(); # get base url
  var string{} view_url    = { # build url hash
                              "recent"   => "$base_url/",
                              "friends"  => "$base_url/friends/",
                              "archive"  => "$base_url/calendar/",
                              "userinfo" => "$*SITEROOT/userinfo.bml?user=$p.journal.username&mode=full"
                             };
  foreach var string v ($views_order) {
    $content = $content + """<li class="links"><a href="$view_url{$v}">$view_text{$v}</a></li>\n""";
  }
  $content = $content + "</ul>";
  print_box($header, $content);

  $p->print_linklist();

  """
          </div>
        </td>
  """;
}

function num_comments_in_thread (Comment[] comments) : int {
  var int total = 0;
  foreach var Comment c ($comments) {
    $total = $total + 1;
    if (size $c.replies > 0) {
      $total = $total + num_comments_in_thread($c.replies);
    }
  }
  return $total;
}

function Page::print_linklist() {
  if (size $.linklist <= 0) {
    return;
  }
  var string links;
  foreach var UserLink l ($.linklist) {
    if ($l.title) {
      if ($l.is_heading) {
        $links = $links + """<li class="links_header">$l.title</li>\n""";
      } else {
        $links = $links + box_item("""<li class="links"><a href="$l.url">$l.title</a></li>\n""");
      }
    }
  }
  print_linkbox($*links_header, $links); 
}

function Page::lay_print_calendar ()  {
  var YearMonth m = $this->get_latest_month();
  var string mon = $m->month_format();
  var string text;
  $text = """<table cellspacing="2" cellpadding="2" border="0" width="100%">\n""";
  foreach var YearWeek w ($m.weeks) {
    $text = $text + "<tr>\n";
    if($w.pre_empty > 0) {
      foreach var int empty (1..$w.pre_empty)  {
        $text = $text + """<td class="calempty">&nbsp;</td>\n""";
      }
    }
    foreach var YearDay d ($w.days) {
      if($d.num_entries > 0) {
        $text = $text + """<td class="calendarActive"><a href="$d.url">$d.day</a></td>\n""";
      } else {
        $text = $text + """<td class="calendarInactive">$d.day</td>\n""";
      }
    }
    $text = $text + "</tr>\n";
  }
  $text = $text + "</table>";
  print_box($mon, $text);
}


function Page::lay_print_subnav ()  { }

function RecentPage::lay_print_subnav ()  {
  var string back;
  if($.nav.backward_url != "") {
    $back = """<a href="$.nav.backward_url">""" + rehtml(get_plural_phrase($.nav.backward_skip, "text_skiplinks_back")) + "</a>";
  } else {
    $back = "&nbsp;";
  }
  var string forward;
  if($.nav.forward_url != "") {
    $forward = """<a href="$.nav.forward_url">""" + rehtml(get_plural_phrase($.nav.forward_skip, "text_skiplinks_forward")) + "</a>";
  } else {
    $forward = "&nbsp;";
  }
  var int    start = $.nav.skip;
  var int    end   = $.nav.skip + size $.entries;
  var string text  = "$start - $end";
  print """<div class="systemmessage">""" + rehtml($back) + " | $text | " + rehtml($forward) + "</div>";
}

function FriendsPage::lay_make_username (Entry e) {
  var Friend f = $.friends{$e.journal.username};
  var string url = $e.poster->base_url();
  """<a href="$url" class="friendname" style="color: $f.fgcolor; background-color: $f.bgcolor;">$e.poster.username</a>""";
  if($e.poster.username != $e.journal.username) {
    """ $e.journal""";
  }
}

function EntryPage::print_body() {
  $this->print_entry($.entry);
  if ($this.multiform_on) {
    $this->print_multiform_start();
  }

  if ($.entry.comments.count > 0) {
    """<h3>Comments</h3>\n""";
  }
	
  if ($.comment_pages.total_subitems > 0) {
    $.comment_pages->print();
  }

  if ($.entry.comments.enabled) {
    $this->print_comments($.comments);
  }

  if ($.entry.comments.count > 0) {
    """<div class="systemmessage">\n""";
    $.entry.comments->print();
    """</div>""";
  }

  if ($.comment_pages.total_subitems > 0) {
    $.comment_pages->print();
  }

  if ($this.multiform_on and ($.entry.comments.count > 0)) {
    """<div class="replyform">\n""";
    $this->print_multiform_actionline();
    """</div>\n""";
    $this->print_multiform_end();
  }
}

function EntryPage::print_comments(Comment[] cs) {
  if (size $cs == 0) { return; }
  foreach var Comment c ($cs) {
    if ($c.full) {
      $this->print_comment($c);
    } else {
      $this->print_comment_partial($c);
    }
  }
}

function EntryPage::print_comment(Comment c) {
  var string datetime;
  $datetime = $c.time->date_format("long")+", " + $c.time->time_format();
  var string picword;
  if (defined $c.userpic and $*comment_userpic_style !="off") {
    $picword = $c.metadata{"picture_keyword"};

  }
  var string parent;
  var string thread;
  if($c.parent_url != "") {
    $parent = """<a href="$c.parent_url">$*text_comment_parent</a>$*t_divider""";
  }
  if($c.thread_url != "") {
    $thread = """<a href="$c.thread_url">$*text_comment_thread</a>$*t_divider""";
  }
  var string subjecticon;
  if (defined $c.subject_icon) {
    $subjecticon = """<img src="$c.subject_icon.url" width="$c.subject_icon.width" height="$c.subject_icon.height" alt="" />""";
  }
  var string ip;
  if ($c.metadata{"poster_ip"}) { 
    $ip = """ &nbsp;  """ + $c.metadata{"poster_ip"}; 
  }
  var string poster = defined $c.poster ? $c.poster->as_string() : "<b>(Anonymous)</b>";
  var string poster_name; $poster_name= $c.poster.name;
  var string pic;
  if (defined $c.userpic and $*comment_userpic_style != "off") {
    $pic = """<img src="$c.userpic.url" width="$c.userpic.width" height="$c.userpic.height" alt="$picword" title="$picword" />""";
  }
  var string indent = ($c.depth - 1) * 25 + "px";
  """
  <a name='$c.anchor'></a>
  <div class="comment_wrapper">
    <table class="comment_info">
      <tr>
        <td>
          <div class="comment_postedby">Posted by: $poster_name ($poster)  <span class="ip">$ip</span></div>
          <div class="comment_date">Posted at: $subjecticon $datetime</div>
  """;
	
  if ($.multiform_on) {
    """
          <div class="comment_date"><label for="ljcomsel_$c.talkid">$*text_multiform_check</label>
    """; 
    $c->print_multiform_check();
    "
          </div>
    ";
  }
  """
          <div class="comment_subject">$c.subject</div>
        </td>
        <td valign="top">$pic</td>
      </tr>
    </table>
    <div class="entrytext"><p>"""; $c->print_text(); """</p> </div>
    <div class="comment_links"> <a href="$c.reply_url">$*text_comment_reply</a>$*t_divider

      <a href="$c.permalink_url">$*text_permalink</a>$*t_divider $parent$thread
    </div>
  """;

  if ((size $c.replies) > 0 and $c.replies[0].full == false) {
    """
    <div class="comment_child">\n""";
    $this->print_comments($c.replies);
    "
    </div>\n";
  }

  """
  </div>
  """;
  if ((size $c.replies) > 0 and $c.replies[0].full == true) {
    """
  <div class="comment_child">
    """;
    $this->print_comments($c.replies);
    """
  </div>
    """;
  }
}

function EntryPage::print_comment_partial(Comment c) {
  var string poster = defined $c.poster ? $c.poster->as_string() : "<i>(Anonymous)</i>";
  var string subj   = $c.subject != "" ? $c.subject : """<i class="nosubject">$*text_nosubject</i>""";
  var string indent = ($c.depth - 1) * 25 + "px";
  """
  <div class="entry" style="margin-left: $indent;">
    <div class="minicommentholder">
      <div class="minicomment">$poster - <a href="$c.permalink_url">$subj</a></div>
    </div>
  </div>
  """;
  $this->print_comments($c.replies);
}

function ItemRange::print() {
  if ($.all_subitems_displayed) { return; }
  """
  <div class="systemmessage">
    <b>
  """;
  print lang_page_of_pages($.current, $.total);
  "</b> &mdash; ";
  foreach var int i (1..$.total) {
    if ($i == $.current) {
      """<b class="systemtext">[$i]</b>""";
    } else { 
      var string url_of = $this->url_of($i);
      "<a href='$url_of'><b>[$i]</b></a>";
    }
  }
  """</div>""";
}

function Entry::print_linkbar() {
  var string   link_seperator = $*t_divider; # seperator for links

  # initialize array/hashes
  var string[] link_keyseq    = [""];
  var string{} link_url       = {"" => ""};
  var string{} link_caption   = {"" => ""};
  var string{} link_image     = {"" => ""};

  var string print           = "";                                         # var for printing
  var Page   p               = get_page();                                 # page handle to determine interentry
  var bool   show_interentry = ($p.view == "entry" or $p.view == "reply"); # if entry/reply view, show interentry
  var int    keyseq_index    = 0;                                          # set index point for new link_keyseq array

  if($show_interentry) {
    # if show interentry, put previous entry link first
    $link_keyseq[$keyseq_index++] = "nav_prev";

    # get previous entry link information
    var Link prev             = $this->get_link("nav_prev");
    $link_url{"nav_prev"}     = $prev.url;
    $link_caption{"nav_prev"} = $prev.caption;
    $link_image{"nav_prev"}   = $prev.icon.url;

    # get next entry link information
    var Link next             = $this->get_link("nav_next");
    $link_url{"nav_next"}     = $next.url;
    $link_caption{"nav_next"} = $next.caption;
    $link_image{"nav_next"}   = $next.icon.url;
  }

  # gather current linkbar
  foreach var string link_key ($.link_keyseq) {
    var Link  link            = $this->get_link($link_key);
    $link_url{$link_key}      = $link.url;
    $link_caption{$link_key}  = $link.caption;
    $link_image{$link_key}    = $link.icon.url;
    $link_keyseq[$keyseq_index++] = $link_key; # add this to new link_keyseq array
  }
  if($show_interentry) {
    # if show interentry, put next entry link last
    $link_keyseq[$keyseq_index++] = "nav_next";
  }

  #################################################################################################################
  # by now, the above hashes should look something like:                                                          #
  #                                                                                                               #
  # If interentry:                                                                                                #
  #   Previous Entry:                                                                                             # 
  #    $link_url{"nav_prev"}     = http://www.livejournal.com/go.bml?journal=exampleusername&itemid=256&dir=prev  #
  #    $link_caption{"nav_prev"} = Previous Entry                                                                 #
  #    $link_image{"nav_prev"}   = http://stat.livejournal.com/img/btn_prev.gif                                   #
  #                                                                                                               #
  # Edit Entry:                                                                                                   # 
  #  $link_url{"edit_entry"}     = http://www.livejournal.com/editjournal.bml?journal=exampleusername&itemid=256  #
  #  $link_caption{"edit_entry"} = Edit Entry                                                                     #
  #  $link_image{"edit_entry"}   = http://stat.livejournal.com/img/btn_edit.gif                                   #
  #                                                                                                               #
  # Edit Tags:                                                                                                    # 
  #  $link_url{"edit_tags"}      = http://www.livejournal.com/edittags.bml?journal=exampleusername&itemid=256     #
  #  $link_caption{"edit_tags"}  = Edit Tags                                                                      #
  #  $link_image{"edit_tags"}    = http://stat.livejournal.com/img/btn_edittags.gif                               #
  #                                                                                                               #
  # Add to Memories:                                                                                              # 
  #  $link_url{"mem_add"}        = http://www.livejournal.com/tools/memadd.bml?journal=exampleusername&itemid=256 #
  #  $link_caption{"mem_add"}    = Add to Memories                                                                #
  #  $link_image{"mem_add"}      = http://stat.livejournal.com/img/btn_memories.gif                               #
  #                                                                                                               #
  # If interentry:                                                                                                #
  #   Next Entry:                                                                                                 #
  #    $link_url{"nav_next"}     = http://www.livejournal.com/go.bml?journal=exampleusername&itemid=256&dir=next  #
  #    $link_caption{"nav_next"} = Next Entry                                                                     #
  #    $link_image{"nav_next"}   = http://stat.livejournal.com/img/btn_next.gif                                   #
  #################################################################################################################

  $link_image{"edit_entry"} = $*i_edit;
  $link_image{"mem_add"}    = $*i_mem;
  $link_image{"edit_tags"}  = $*i_tags;

  $link_caption{"edit_entry"}  = $*t_edit_entry;
  $link_caption{"mem_add"}     = $*t_mem_add;
  $link_caption{"edit_tags"}   = $*t_edit_tags;
  $link_caption{"tell_friend"} = $*t_tell_friend;

  $link_keyseq[size($link_keyseq)] = "permalink";      # add a permalink to end of linkbar
  $link_url{"permalink"}           = $.permalink_url;
  $link_caption{"permalink"}       = $*text_permalink;
  $link_image{"permalink"}         = $*i_perma;

  # loop thru linkbar and add links to print var
  foreach var string link_key ($link_keyseq) {
    # if we can do performed action, url will be present
    if($link_url{$link_key} != "") {
      $print = $print + """<a href="$link_url{$link_key}" title="$link_caption{$link_key}">""";
      # if image url available, use it
      if(($link_image{$link_key} != "") and ($*image_links == true)) {
        $print = $print + """<img src="$link_image{$link_key}" alt="$link_caption{$link_key}" title="$link_caption{$link_key}" border="0" />""";
      } else {
        # else, just use text
        $print = $print + "$link_caption{$link_key}";
      }
      # add a seperator
      $print = $print + "</a>$link_seperator";
    }
  }

  # hack off last seperator
  $print = $print->substr(0, $print->length() - $link_seperator->length());

  # we're done! let's print it!
  print $print;
}

function Page::print_entry (Entry e)  {
  # Print an anchor
  """<a name="item$e.itemid" id="item$e.itemid"></a>""";
  # Get the right time and date of the post
  var string time = $e.time->time_format();
  var string date = $e.time->date_format("long");
  # Get the Locked or Private icon, if needed.
  var string security;
  if ($e.security != "") {
    $security =  """<img src="$e.security_icon.url" align="right" width="$e.security_icon.width" height="$e.security_icon.height" alt="[$e.security]" title="[$e.security]" />""";
  }
  var string subject = ($e.subject != "") ? $e.subject : "<i>$*text_nosubject</i>";

  var UserLite name;
  var string pname;
  var string poster_name = $e.poster.name;
  var string poster  = defined $e.poster ? $e.poster->as_string() : "<b>$*text_poster_anonymous</b>";
  var bool show_name = ($.view == "friends" or $e.poster.username != $.journal.username or $.view == "entry") ? true : false;
  var bool show_pic  = (defined $e.userpic and ($.view == "friends" or $*show_entry_userpic or $e.poster.username != $e.journal.username or $.view == "entry")) ? true : false;

  """
  <div class="comment_wrapper">
  """;
  if($show_pic) {
    """
    <div class="userpic2">
      <img src="$e.userpic.url" width="$e.userpic.width" height="$e.userpic.height" alt="$e.poster.name [userpic]" title="$e.poster.name [userpic]" border="0" />
    </div>
    """;
  }
  """
    <div class="comment_subject">$security $subject</div>
    <div class="comment_postedby">
  """;
  if(true) {
    var string date_time = "$date ($time)";
    if($.view == "friends" or $e.journal.journal_type == "C") {
      $date_time = "at $date_time";
    }
    if($.view == "friends" or $e.journal.journal_type == "C") {
      if($e.journal.journal_type == "C") {
        """
    in $e.journal<br />
        """;
      }
      """
    by $poster_name ($poster)
      """;
    }
    """
    <div class="comment_date">$date_time</div>
    """;  
  }
  $e->print_metadata();
  """
    </div>
  <div class="entrytext"><p>"""; $e->print_text(); """</p></div>
  <div class="comment_links">
  """;
  # Prints the row of comment links
  $e.comments->print();
  $e->print_linkbar();
  """
  </div>
</div>
  """;
}

function CommentInfo::print() {
  if ($.enabled) {
    if ($.count > 0 or $.screened) {
      $this->print_readlink();
    }
    $this->print_postlink();
  }
}

function CommentInfo::print_postlink() {
  var Page p = get_page();
  var string alttext = $p.view == "friends" ? $*text_post_comment_friends : $*text_post_comment;
  """<a href="$.post_url">""";
  if($*image_links) {
    """<img src="$*i_leave" border="0" title="$alttext" alt="$alttext" />""";
  } else {
    print $alttext;
  }
  """</a>$*t_divider""";
}

function CommentInfo::print_readlink {
  var Page p = get_page();
  var string alttext = get_plural_phrase($.count, $p.view == "friends" ? 
                               "text_read_comments_friends" :
                               "text_read_comments"
                     );
  """<a href="$.read_url">""";
  if($*image_links) {
    """<img src="$*i_comment" border="0" title="$alttext" alt="$alttext" />""";
  } else {
    print $alttext;
  }
  """</a>$*t_divider""";
}

function DayPage::lay_print_subnav ()  {
  var string back;
  if($.prev_url != "") {
    $back = """<a href="$.prev_url">""" + rehtml($*text_day_prev) + "</a>";
  } else {
    $back = "&nbsp;";
  }
  var string forward;
  if($.next_url != "") {
    $forward = """<a href="$.next_url">""" + rehtml($*text_day_next) + "</a>";
  } else {
    $forward = "&nbsp;";
  }
  var string text = $.date->date_format("long");
  """<div class="systemmessage">$back | $text | $forward</div>""";
}



############################# REPLY PAGE #########################################

function ReplyPage::print_body() {
  var EntryLite e     = $.replyto;
  var string poster   = defined $e.poster ? $e.poster->as_string() : "<i>(Anonymous)</i>";
  var string datetime;
  var string time     = $e.time->time_format();
  var string date     = $e.time->date_format("long");

  var UserLite name;
  """	
  <div class="entry">
    <h3>$date</h3>
  """;
  if(defined $e.userpic and $*comment_userpic_style != "off") {
    $name = $e.poster;
    """
      <div class="userpic_reply">
    """;
    if (defined $e.userpic or (defined $e.userpic and $.view == "entry" and $*show_entry_userpic)) {
      """
        <img src="$e.userpic.url" width="$e.userpic.width" height="$e.userpic.height" alt="" />
      """;
    }
    """
      </div>
    """;
  }
  """
    <h1>$e.subject</h1>
    <div class="entrytext">
      <p>"""; $e->print_text(); """</p>
    </div>
    <div class="entrylinks">
      Posted at $time $*t_divider <a href="$.entry.comments.read_url" class="comments">$*text_reply_back</a>
  """;
  foreach var string key (["edit_entry","mem_add","edit_tags"]) {
    var Link link = $e->get_link($key);
    if ($link) {
      """$*t_divider <a href=\"$link.url\">$link.caption</a>""";
    }
  }
  """ $*t_divider <a href="$e.permalink_url">$*text_permalink</a>
    </div>
    <div class="replyform">
  """;
  $.form->print();
  """
    </div>
  </div>
  """;
}

function Entry::print_metadata() {
  var string tags_header = "tags";
  var string tags_joiner = ":";
  var Link   edit_tags   = $this->get_link("edit_tags");
  var string currents    = "";
  if ((size $.metadata > 0) or ((size $.tags > 0) and ($*tags_aware))){
    $currents = $currents + """<div class="currents">""";
    foreach var string k ($.metadata){
      var string text = $k;
      var string val = $.metadata{$k};
      if ($k == "mood"){
        $text = $*text_meta_mood;
      } 
      elseif ($k == "music") {
        $text = $*text_meta_music;
      }
      if ($k == "mood" and defined $.mood_icon){
        var Image i = $.mood_icon;
        $val = "<img src='$i.url' width='$i.width' height='$i.height' align='middle' alt='' /> $val";
      }
      $currents = $currents + """<div class="current$k"><strong>$text</strong> $val</div>""";        
    }
    if ((size $.tags > 0) and $*tags_aware) {
      var int    tcount               = 0;
      if($edit_tags.url != "") {
        $tags_header = """<a href="$edit_tags.url">$tags_header</a>""";
      }
      $currents = $currents + """<div class="currenttags"><strong>$tags_header$tags_joiner</strong> """;
      var string tags_root = $.journal->base_url() + "/tag";
      foreach var Tag t ($.tags) {
        $currents = $currents + """<a rel="tag" href="$tags_root/$t.name">$t.name</a>""";
        $tcount++;
        if ($tcount != size $.tags) { $currents = $currents + ", "; }
      }
      $currents = $currents + "</div>";
    }
    $currents = $currents + "</div>";
    println "$currents";
  }
}


################################ VIEWS #########################################

function RecentPage::print_body ()  {
  """
  <div class="entries">
  """;
  foreach var Entry e ($.entries) {
    $this->print_entry($e);
  }
  """
  </div>
  """;
}

function DayPage::print_body() {
  """<div class="entries">""";
  if ($.has_entries) {
    foreach var Entry e ($.entries) {
      $this->print_entry($e);
    }
  } else {
    "<p>$*text_noentries_day</p>";
  }
  "</div>";
}

function MonthPage::view_title : string {
  return $.date->date_format($*lang_fmt_month_long);
}

function MonthPage::print_body {
  "<form method='post' action='$.redir.url'>";
  $.redir->print_hiddens();
  var string back;
  var string forward;
  if ($.prev_url != "") { $back = """<a href="$.prev_url">back</a>"""; }
  if ($.next_url != "") { $forward = """<a href="$.next_url">forward</a>"""; }
  var string select;
  if (size $.months > 1) {
    $select = "<select name='redir_key'>\n";
    foreach var MonthEntryInfo mei ($.months) {
      var string sel;
      if ($mei.date.year == $.date.year and $mei.date.month == $.date.month) {
        $sel = " selected='selected'";
      }
      $select = $select + "<option value='$mei.redir_key'$sel>" + $mei.date->date_format($*lang_fmt_month_long) + "</option>";
    }
    $select = $select + "</select>\n<input type='submit' value='View' />";
  }
  """
  <div class="messageholder">
    <div class="systemmessage">
      <table cellspacing="0" cellpadding="0" border="0" width="100%">
        <tr>
          <td width="15%">$back</td>
          <td align="center" width="70%">$select</td>
          <td align="right" width="15%">$forward</td>
        </tr>
      </table>
    </div>
  </div>
  """;
  "</form>";
  foreach var MonthDay d ($.days) {
    if ($d.has_entries) {
      """
      <a name="anchor$d.day" id="achor$d.day"></a>
        <div class="entry">
          <div class="entrydivider"></div>
          <div class="entrylinks">
            <a href=\"$d.url\"> &nbsp; <b>
      """;
      print lang_ordinal($d.day);
      """
            </b> &nbsp; </a></div>
            <div class="entries">
              <div class="entrytext">
      """;
      $d->print_subjectlist();
      """
              </div>
            </div>
          </div>
      """;
    }
  }
}

function MonthDay::print_subjectlist() {
  foreach var Entry e ($.entries) {
    print $e.time->time_format("short") + ": ";
    if ($e.poster.username != $e.journal.username) {
      $e.poster->print(); " ";
    }
    "$e.security_icon";
    if ($e.subject != "") {
      " <a href=\"$e.permalink_url\">$e.subject</a>";
    } else {
      """ <a href="$e.permalink_url"><i class="nosubject">$*text_nosubject</i></a>""";
    }
    if ($e.comments.count > 0) {
      " - " + get_plural_phrase($e.comments.count, "text_read_comments");
    }
    if ($e.comments.screened) {
      " <b>$*text_month_screened_comments</b>";
    }
    "<br />\n";
  }
}

function YearPage::print_body {
  $this->print_year_links();
  """<div id="cal">""";
  foreach var YearMonth m ($.months) {
    $this->print_month($m);
  }
  """</div>""";
}

function YearPage::print_year_links() {
  """<div class="systemmessage">""";
  foreach var YearYear y ($.years) {
    if ($y.displayed) {
      """<b class="systemtext">$y.year</b>""";
    } else {
      """<b>$*t_divider<a href="$y.url">$y.year</a>$*t_divider</b>""";
    }
  }
  """</div>""";
}

function YearPage::print_month(YearMonth m) {
  if (not $m.has_entries) { return; }
  """
  <a name="anchor$m.month"></a>
  <div class="entry">
    <div class="entrydivider"></div>
    <div class="entryinfo">
  """;
  print $m->month_format();
  """
    </div>
    <div class="entrylinks"><a href="$m.url">$*text_view_month</a></div>
    <div class="entrytext">
      <div align="center">
        <table cellspacing="0" cellpadding="0" border="0" width="100%">
          <tr>
  """;
  foreach var int d (weekdays()) {
    """
            <td width="14%"><div class="calendarInactive">$*lang_dayname_short[$d]</div></td>
    """;
  }
  """
          </tr>
  """;
  foreach var YearWeek w ($m.weeks) {
    $w->print();
  }
  """
        </table>
      </div>
    </div>
  </div>
  """;
}

function YearWeek::print() {
  """
          <tr>
  """;
  if ($.pre_empty > 0) {
    """
            <td colspan="$.pre_empty"></td>
    """;
  }

  foreach var YearDay d ($.days) {
    var string day = zeropad($d.day, 2);
    """
            <td>
              <div class="calendarInactive">$day</div>
    """;
    if ($d.num_entries > 0) {
      var string num = $d.num_entries < 10 ? "&nbsp;" + string($d.num_entries) : string($d.num_entries);
      """
              <div class="calendarActive"><a href="$d.url">$num</a></div>
      """;
    } else {
      """
              <div class="calendarInactive"> - </div>
      """;
    }
    """
            </td>
    """;
  }
  """
          </tr>
  """;
}

############################## COMMON HTML ############################################

function Page::print() {
  var string title = $this->title();
  """
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="" lang="">
  <head>
    <title>$title</title>
    <link rel="stylesheet" href="$.stylesheet_url" type="text/css" />
  """;
  $this->print_head();
  """
  </head>
  <body>
    <a name="top"></a>
  """;
  if($*header_image != "") {
  """
    <div align="center"><img src="$*header_image" alt="" title="" /></div>
  """;
  }
  """
    <table border="0" cellpadding="0" cellspacing="0" width="100%">
      <tr>
  """;
  print_left_bar();
  """
        <td id="container" valign="top">
          <div>
            <div id="entries">
  """;
  $this->lay_print_subnav();
  $this->print_body();
  $this->lay_print_subnav();
  """
            </div>
          </div>
        </td>
  """;
  print_right_bar();
  """
      </tr>
    </table>
  </body>
</html>
  """;
}

first post

kunzite1 — Sun, 03 Jul 2005 16:50:30 GMT

s2ljdotcom was created for me to post "fixed" versions of the layouts here on livejournal.com.

If property names are changed, give a mapping diagram like:

text:
nav_recent_text -> text_view_recent

colors:
calendar_fgcolor -> calendar_active_fgcolor