# Maintainer: Paul Dann <pdgiddie at gmail dot com>
pkgname=multiwatch
pkgver="1.0.1"
pkgrel=1
pkgdesc="Forks and watches multiple instances of a program in the same context"
arch=('i686' 'x86_64')
url="http://redmine.lighttpd.net/projects/multiwatch/wiki"
license=("MIT")
depends=("libev")
makedepends=("meson")
source=("https://download.lighttpd.net/multiwatch/releases-1.x/multiwatch-$pkgver.tar.xz"
        "https://download.lighttpd.net/multiwatch/releases-1.x/multiwatch-$pkgver.tar.xz.asc")
b2sums=('b82b47b5409c01099c255ad71052c2422461961cf747b663561e34e55af4959105c3f8a07074faae1df78befc8d207d3d5f04e69f0e7f0a2649364da1d753832'
        'SKIP')
validpgpkeys=("C7CA1E9E29DC77F5480894B2E0E7D0171E95BAD7")



build() {
  cd "$srcdir/$pkgname-$pkgver"
  
  arch-meson . build/
  meson compile -C build/
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  
  meson install -C build/ --destdir "$pkgdir"
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:set ts=2 sw=2 et: