load("//tools/build_defs/proto:proto_common.bzl", "proto_common")

def output_dir(ctx, proto_info):
    """Returns the output directory where generated proto files will be placed.

    Args:
      ctx: Rule context.
      proto_info: ProtoInfo provider.

    Returns:
      A string specifying the output directory
    """
    proto_root = proto_info.proto_source_root
    if proto_root.startswith(ctx.bin_dir.path):
        path = proto_root
    else:
        path = ctx.bin_dir.path + "/" + proto_root

    if proto_root == ".":
        path = ctx.bin_dir.path
    return path

def proto_common_compile(ctx, proto_info, proto_lang_toolchain_info, generated_files):
    """A wrapper around proto_common.compile that automatically calculates the output dir.

    Args:
      ctx: Rule context.
      proto_info: ProtoInfo provider.
      proto_lang_toolchain_info: ProtoLangToolchainInfo provider.
      generated_files: The files we expect to be generated from this protoc invocation.
    """
    proto_common.compile(
        actions = ctx.actions,
        proto_info = proto_info,
        proto_lang_toolchain_info = proto_lang_toolchain_info,
        generated_files = generated_files,
        plugin_output = output_dir(ctx, proto_info),
    )