let
  lib = import ./lib;
  githubTeams = lib.importJSON ./maintainers/github-teams.json;
  expectedPairs = [
    "acme"
    "bazel"
    "coq"
    "dotnet"
    "emacs"
    "gitlab"
    "kodi"
    "lxc"
    "mate"
    { github = "nix-formatting"; libTeam = "formatter"; }
    { github = "nix-team"; libTeam = "nix"; }
    "node"
    "xfce"
  ];

  pairsLibToGh = lib.listToAttrs (lib.map (v: lib.nameValuePair (v.libTeam or v) (v.github or v)) expectedPairs);
  libToGh = lib.mapAttrs (ln: lv: lv.github or pairsLibToGh.${ln} or null) lib.teams;

  ghMap = lib.mapAttrs' (ln: lv: lib.nameValuePair lv.github ln) (lib.filterAttrs (ln: lv: lv ? github) lib.teams);
  pairsGhToLib = lib.listToAttrs (lib.map (v: lib.nameValuePair (v.github or v) (v.libTeam or v)) expectedPairs);
  ghToLib = lib.mapAttrs (ghn: ghv: ghMap.${ghn} or pairsGhToLib.${ghn} or null) githubTeams;

  ghCommon = lib.filterAttrs (ghn: ln: ln != null) ghToLib;

  ghMembers = ghn: lib.map lib.toLower (lib.attrNames (githubTeams.${ghn}.maintainers // githubTeams.${ghn}.members));
  #idToHandle = lib.mapAttrs' (_: v: lib.nameValuePair (toString v.githubId) v.github) lib.maintainers;
  libMembers = ln: lib.map (m: lib.toLower m.github) lib.teams.${ln}.members;

  memberMismatch = lib.filterAttrs (ghn: { ln, onlyGh, onlyLib }: onlyGh != [] || onlyLib != []) (lib.mapAttrs (ghn: ln:
    let
      gh = lib.sort builtins.lessThan (ghMembers ghn);
      l = lib.sort builtins.lessThan (libMembers ln);
    in
    {
      inherit ln;
      onlyGh = lib.subtractLists l gh;
      onlyLib = lib.subtractLists gh l;
    }
  ) ghCommon);

  ghWithoutLib = lib.attrNames (lib.filterAttrs (gn: ln: ln == null) ghToLib);

  nameMismatch = lib.filterAttrs (ghn: ln: ghn != ln) ghCommon;

  maintainerLess = lib.attrNames (lib.filterAttrs (ghn: ghv: ghv.maintainers == {}) githubTeams);

  libWithoutGh = lib.attrNames (lib.filterAttrs (ln: gn: gn == null) libToGh);

  teamsWithPos = import ./maintainers/team-list.nix { inherit lib; };
  libPos = ln: "https://github.com/NixOS/nixpkgs/blob/8f87d1d5160c7a28197f78064cc9a5b3a05e908c/maintainers/team-list.nix#L${toString (builtins.unsafeGetAttrPos ln teamsWithPos).line}";
  #res = lib.filterAttrs (ghn: _: (lib.attrNames githubTeams)
  res = {
    inherit ghWithoutLib memberMismatch nameMismatch maintainerLess libWithoutGh;
    #inherit ghToLib libToGh memberMismatch;
    #x = ghToMembers "haskell";
  };

  prettyGhTeam = ghn: "[`@NixOS/${ghn}`](https://github.com/orgs/NixOS/teams/${ghn})";
  prettyGhHandle = handle: "[`@${handle}`](https://github.com/${handle})";
  prettyLibTeam = ln: "[`lib.teams.${ln}`](${libPos ln})";

  string = ''
    GitHub teams that don't have an corresponding entry in `lib.teams`:
    ${lib.concatStrings (lib.map (ghn: "- [ ] [`@NixOS/${ghn}`](https://github.com/orgs/NixOS/teams/${ghn})\n") ghWithoutLib)}
    `lib.teams` that don't have a corresponding GitHub team:
    ${lib.concatStrings (lib.map (ln: "- [ ] ${prettyLibTeam ln}\n") libWithoutGh)}
    Corresponding teams whose members don't match between GitHub and `lib.teams`:
    ${lib.concatStrings (lib.mapAttrsToList (ghn: { ln, onlyGh, onlyLib }: ''
      - [ ] ${prettyGhTeam ghn}/${prettyLibTeam ln}:
      ${lib.optionalString (onlyGh != []) "  - Only on GitHub: ${lib.concatMapStringsSep ", " prettyGhHandle onlyGh}\n"}${lib.optionalString (onlyLib != []) "  - Only in `lib.teams`: ${lib.concatMapStringsSep ", " prettyGhHandle onlyLib}\n"}'') memberMismatch)}
    GitHub teams whose name doesn't match the corresponding `lib.teams`:
    ${lib.concatStrings (lib.mapAttrsToList (ghn: ln: ''
      - [ ] ${prettyGhTeam ghn} <-> ${prettyLibTeam ln}
    '') nameMismatch)}
    GitHub teams that don't have a maintainer:
    ${lib.concatStrings (lib.map (ghn: "- [ ] ${prettyGhTeam ghn}\n") maintainerLess)}
  '';
in
builtins.trace (lib.generators.toPretty {} res)
builtins.trace string null