I've managed to get this far with it, but I'm having some trouble with the directory it's executing in. It's attempting to read/write the plugins directory to the electron lib path:

access("/nix/store/vxcdxq109bsrwhzyhs254s1ghlxf8swz-electron-25.3.1/lib/electron/resources/static/resources/plugins", F_OK) = -1 ENOENT (No such file or directory)
mkdir("/nix/store/vxcdxq109bsrwhzyhs254s1ghlxf8swz-electron-25.3.1/lib/electron/resources/static/resources/plugins", 0777) = -1 ENOENT (No such file or directory)

Not really sure how to work around this. I've opted to build from source to easily support Darwin etc. but I might need to throw in the towel soon and use the Linux Appimage. Excuse the mess, I've been deep in trying to debug the issue and throwing solutions at the wall.

{ lib
, stdenv
, fetchFromGitHub
, makeWrapper
, makeDesktopItem
, fixup_yarn_lock
, yarn
, nodejs_18
, python3
, fetchYarnDeps
, electron
, sqlcipher
, callPackage
, desktopToDarwinBundle
, nest-cli
, libsass
, srcOnly
, buildPackages
, pkg-config
, sqlite
, xdg-utils
}:
let
  nodejs = nodejs_18;
in
stdenv.mkDerivation (finalAttrs: {
  pname = "redisinsight-electron";
  version = "2.30.0";

  src = fetchFromGitHub {
    owner = "RedisInsight";
    repo = "RedisInsight";
    rev = "${finalAttrs.version}";
    hash = "sha256-TzqbMycKcOlUSKvfghip/KdMRiwstkFP+iJG5/9JVlA=";
  };

  offlineCache = fetchYarnDeps {
    yarnLock = finalAttrs.src + "/yarn.lock";
    sha256 = "sha256-aDr5wxM/Rp3Tj09nPpLPJHSG5A73+4rAfrMCcxCr7so=";
  };

  feOfflineCache = fetchYarnDeps {
    yarnLock = finalAttrs.src + "/redisinsight/yarn.lock";
    sha256 = "sha256-O+8lNDrqPdxE+tgjpKbgm9Q66VlJaJgZRHlNyaFkumM=";
  };

  apiOfflineCache = fetchYarnDeps {
    yarnLock = finalAttrs.src + "/redisinsight/api/yarn.lock";
    sha256 = "sha256-2Tvck+9MDj6s+7jehUEyPfJiFFxbMOYDFD/Qgt2En6c=";
  };
  
  nativeBuildInputs = [ yarn fixup_yarn_lock nodejs makeWrapper python3 nest-cli libsass pkg-config ]
    ++ lib.optionals stdenv.isDarwin [ desktopToDarwinBundle ];

  buildInputs = [ sqlite xdg-utils ];
  
  configurePhase = ''
    runHook preConfigure

    export HOME=$(mktemp -d)
    yarn config --offline set yarn-offline-mirror $offlineCache
    fixup_yarn_lock yarn.lock
    yarn install --offline --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive

    yarn config --offline set yarn-offline-mirror $feOfflineCache
    fixup_yarn_lock redisinsight/yarn.lock
    yarn --offline --cwd redisinsight/ --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive

    yarn config --offline set yarn-offline-mirror $apiOfflineCache
    fixup_yarn_lock redisinsight/api/yarn.lock
    yarn --offline --cwd redisinsight/api/ --frozen-lockfile --ignore-platform --ignore-scripts --no-progress --non-interactive

    patchShebangs node_modules/
    patchShebangs redisinsight/node_modules/
    patchShebangs redisinsight/api/node_modules/

    mkdir -p "$HOME/.node-gyp/${nodejs.version}"
    echo 9 >"$HOME/.node-gyp/${nodejs.version}/installVersion"
    ln -sfv "${nodejs}/include" "$HOME/.node-gyp/${nodejs.version}"
    export npm_config_nodedir=${nodejs}

    pushd redisinsight
    # Build the sqlite3 package.
    npm_config_node_gyp="${buildPackages.nodejs}/lib/node_modules/npm/node_modules/node-gyp/bin/node-gyp.js" npm rebuild --verbose --sqlite=${sqlite.dev} sqlite3
    popd

    runHook postConfigure
  '';

  dontPatchShebangs = true;

  buildPhase = ''
    runHook preBuild
    yarn config --offline set yarn-offline-mirror $offlineCache

    pushd node_modules/node-sass
    LIBSASS_EXT=auto yarn run build --offline
    popd

    yarn --offline build:prod

    runHook postBuild
  '';
  
  installPhase = ''
    runHook preInstall

    # resources
    mkdir -p "$out/share/redisinsight"
    mkdir -p "$out/share/redisinsight/resources/static/plugins"
    mkdir -p "$out/share/redisinsight/resources/static/resources/plugins"
    cp -r './redisinsight' "$out/share/redisinsight/electron"
    cp -r './resources' "$out/share/redisinsight"
    # rm -rf "$out/share/redisinsight/electron/node_modules"
    cp -r './node_modules' "$out/share/redisinsight/electron"

    # icons
    for icon in $out/share/redisinsight/electron/resources/icons/*.png; do
      mkdir -p "$out/share/icons/hicolor/$(basename $icon .png)/apps"
      ln -s "$icon" "$out/share/icons/hicolor/$(basename $icon .png)/apps/redisinsight.png"
    done

    # desktop item
    mkdir -p "$out/share"
    ln -s "${finalAttrs.desktopItem}/share/applications" "$out/share/applications"

    makeWrapper '${electron}/bin/electron' "$out/bin/redisinsight" \
      --add-flags "$out/share/redisinsight/electron" \
      --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}" \
      --chdir "$out/share/redisinsight" \
      --inherit-argv0

    runHook postInstall
  '';

  desktopItem = makeDesktopItem {
    name = "redisinsight";
    exec = "redisinsight %u";
    icon = "redisinsight";
    desktopName = "RedisInsight";
    genericName = "RedisInsight Redis Client";
    comment = finalAttrs.meta.description;
    categories = [ "Development" ];
    startupWMClass = "redisinsight";
  };
  
  meta = with lib; {
    description = "RedisInsight Redis client powered by Electron";
    homepage = "https://github.com/RedisInsight/RedisInsight";
    license = licenses.sspl;
    maintainers = [  ];
    platforms = [ "x86_64-linux" ];
  };
})

Uh oh!

Package request: RedisInsight #242438

Description

Metadata

Metadata

Assignees

Labels

Fields

Projects

Milestone

Relationships

Development

Issue actions