lib.teams: Populate fields from synced GitHub state

infinisil · infinisil · commit 2a57eba10889 · 2025-10-28T17:04:25.000+01:00
The before and after of nix-instantiate --eval -A lib.teams --strict --json | jq 'walk(if type == "array" then sort else . end)' has been ensured to be negligible, only consisting of minor team shortName and scope differences (cherry picked from commit 428bd8f)
diff --git a/ci/OWNERS b/ci/OWNERS
@@ -33,6 +33,7 @@
 /lib/path/*                 @infinisil @hsjobeki
 /lib/fileset                @infinisil @hsjobeki
 /maintainers/github-teams.json @infinisil
+/maintainers/computed-team-list.nix @infinisil
 ## Standard environment–related libraries
 /lib/customisation.nix      @alyssais @NixOS/stdenv
 /lib/derivations.nix        @alyssais @NixOS/stdenv
diff --git a/lib/default.nix b/lib/default.nix
@@ -63,7 +63,7 @@ let
       customisation = callLibs ./customisation.nix;
       derivations = callLibs ./derivations.nix;
       maintainers = import ../maintainers/maintainer-list.nix;
-      teams = callLibs ../maintainers/team-list.nix;
+      teams = callLibs ../maintainers/computed-team-list.nix;
       meta = callLibs ./meta.nix;
       versions = callLibs ./versions.nix;
 
diff --git a/maintainers/README.md b/maintainers/README.md
@@ -164,7 +164,6 @@ team after giving the existing members a few days to respond.
 *Important:* If a team says it is a closed group, do not merge additions
 to the team without an approval by at least one existing member.
 
-
 # Maintainer scripts
 
 Various utility scripts, which are mainly useful for nixpkgs maintainers,
diff --git a/maintainers/computed-team-list.nix b/maintainers/computed-team-list.nix
@@ -0,0 +1,49 @@
+# Extends ./team-list.nix with synced GitHub information from ./github-teams.json
+{ lib }:
+let
+  githubTeams = lib.importJSON ./github-teams.json;
+  teams = import ./team-list.nix { inherit lib; };
+
+  # A fast maintainer id lookup table
+  maintainersById = lib.pipe lib.maintainers [
+    lib.attrValues
+    (lib.groupBy (attrs: toString attrs.githubId))
+    (lib.mapAttrs (_: lib.head))
+  ];
+
+  maintainerSetToList =
+    githubTeam:
+    lib.mapAttrsToList (
+      login: id:
+      maintainersById.${toString id}
+      or (throw "lib.teams: No maintainer entry for GitHub user @${login} who's part of the @NixOS/${githubTeam} team")
+    );
+
+in
+lib.mapAttrs (
+  name: attrs:
+  if attrs ? github then
+    let
+      githubTeam =
+        githubTeams.${attrs.github}
+          or (throw "lib.teams.${name}: Corresponding GitHub team ${attrs.github} not known yet, make sure to create it and wait for the regular team sync");
+    in
+    assert lib.assertMsg (!attrs ? shortName)
+      "lib.teams.${name}: Both `shortName` and `github` is set, but the former is synced from the latter";
+    assert lib.assertMsg (
+      !attrs ? scope
+    ) "lib.teams.${name}: Both `scope` and `github` is set, but the former is synced from the latter";
+    assert lib.assertMsg (
+      !attrs ? members
+    ) "lib.teams.${name}: Both `members` and `github` is set, but the former is synced from the latter";
+    attrs
+    // {
+      shortName = githubTeam.name;
+      scope = githubTeam.description;
+      members =
+        maintainerSetToList attrs.github githubTeam.maintainers
+        ++ maintainerSetToList attrs.github githubTeam.members;
+    }
+  else
+    attrs
+) teams
diff --git a/maintainers/team-list.nix b/maintainers/team-list.nix
