Package Details: rbw-git 1.3.0-2

Git Clone URL: https://aur.archlinux.org/rbw-git.git (read-only, click to copy)
Package Base: rbw-git
Description: unofficial bitwarden cli
Upstream URL: https://git.tozt.net/rbw
Licenses: MIT
Conflicts: rbw, rbw-bin
Provides: rbw
Submitter: doy
Maintainer: doy
Last Packager: doy
Votes: 0
Popularity: 0.000000
First Submitted: 2020-05-02 04:30 (UTC)
Last Updated: 2021-07-05 20:17 (UTC)

Required by (7)

Sources (1)

Latest Comments

CupricReki commented on 2026-02-08 03:28 (UTC)

The upstream git repo seems to be unavailable at the moment. I created a more thorough PKGBUILD which points at the github repo. 

# Maintainer: Jesse Luehrs <archlinux@tozt.net>
pkgname=rbw-git
_pkgname=rbw
pkgver=0.1.0.r566.g77464d414a
pkgrel=2
makedepends=('rust' 'cargo' 'git')
depends=('pinentry')
conflicts=("$_pkgname")
provides=("$_pkgname=${pkgver/\.r*/}")
arch=('i686' 'x86_64' 'aarch64')
url="https://github.com/doy/rbw"
source=("$_pkgname"::"git+https://github.com/doy/$_pkgname.git")
sha256sums=('SKIP')
pkgdesc="unofficial bitwarden cli"
license=('MIT')
options=('!lto')

pkgver() {
  cd "$_pkgname"
  git describe --abbrev=10 --long --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$_pkgname"
  cargo fetch --locked
}

build() {
    cd "${_pkgname}"
    export RUSTUP_TOOLCHAIN=stable

    cargo build --frozen --release --all-features
    ./target/release/rbw gen-completions bash > bash-completions
    ./target/release/rbw gen-completions zsh > zsh-completions
    ./target/release/rbw gen-completions fish > fish-completions
}

check() {
  cd "$_pkgname"
  export RUSTUP_TOOLCHAIN=stable
  cargo test --frozen --all-features
}

package() {
    cd "$_pkgname"
    install -Dm0755 target/release/rbw -t "${pkgdir}/usr/bin"
    install -Dm0755 target/release/rbw-agent -t "${pkgdir}/usr/bin"
    install -Dm0644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
    install -Dm0644 bash-completions "${pkgdir}/usr/share/bash-completion/completions/rbw"
    install -Dm0644 zsh-completions "${pkgdir}/usr/share/zsh/site-functions/_rbw"
    install -Dm0644 fish-completions "${pkgdir}/usr/share/fish/vendor_completions.d/rbw.fish"
}